From f44ecaa4f27e7538ddcad66d40e543bffa2d2d86 Mon Sep 17 00:00:00 2001
From: manuel <manuel@mausz.at>
Date: Sun, 4 Jun 2017 16:57:49 +0200
Subject: sync with upstream

---
 cmake/modules/FindCdio.cmake | 45 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 cmake/modules/FindCdio.cmake

(limited to 'cmake/modules/FindCdio.cmake')

diff --git a/cmake/modules/FindCdio.cmake b/cmake/modules/FindCdio.cmake
new file mode 100644
index 0000000..3f0a867
--- /dev/null
+++ b/cmake/modules/FindCdio.cmake
@@ -0,0 +1,45 @@
+#.rst:
+# FindCdio
+# --------
+# Finds the cdio library
+#
+# This will will define the following variables::
+#
+# CDIO_FOUND - system has cdio
+# CDIO_INCLUDE_DIRS - the cdio include directory
+# CDIO_LIBRARIES - the cdio libraries
+#
+# and the following imported targets::
+#
+#   CDIO::CDIO - The cdio library
+
+if(PKG_CONFIG_FOUND)
+  pkg_check_modules(PC_CDIO libcdio libiso9660 QUIET)
+endif()
+
+find_path(CDIO_INCLUDE_DIR NAMES cdio/cdio.h
+                           PATHS ${PC_CDIO_libcdio_INCLUDEDIR}
+                                 ${PC_CDIO_libiso9660_INCLUDEDIR})
+find_library(CDIO_LIBRARY NAMES cdio libcdio
+                          PATHS ${CDIO_libcdio_LIBDIR} ${CDIO_libiso9660_LIBDIR})
+
+set(CDIO_VERSION ${PC_CDIO_libcdio_VERSION})
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(Cdio
+                                  REQUIRED_VARS CDIO_LIBRARY CDIO_INCLUDE_DIR
+                                  VERSION_VAR CDIO_VERSION)
+
+if(CDIO_FOUND)
+  set(CDIO_LIBRARIES ${CDIO_LIBRARY})
+  set(CDIO_INCLUDE_DIRS ${CDIO_INCLUDE_DIR})
+
+  if(NOT TARGET CDIO::CDIO)
+    add_library(CDIO::CDIO UNKNOWN IMPORTED)
+    set_target_properties(CDIO::CDIO PROPERTIES
+                                     IMPORTED_LOCATION "${CDIO_LIBRARY}"
+                                     INTERFACE_INCLUDE_DIRECTORIES "${CDIO_INCLUDE_DIR}")
+  endif()
+endif()
+
+mark_as_advanced(CDIO_INCLUDE_DIR CDIO_LIBRARY)
-- 
cgit v1.2.3