From f44ecaa4f27e7538ddcad66d40e543bffa2d2d86 Mon Sep 17 00:00:00 2001
From: manuel <manuel@mausz.at>
Date: Sun, 4 Jun 2017 16:57:49 +0200
Subject: sync with upstream

---
 cmake/modules/FindTexturePacker.cmake | 41 +++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 cmake/modules/FindTexturePacker.cmake

(limited to 'cmake/modules/FindTexturePacker.cmake')

diff --git a/cmake/modules/FindTexturePacker.cmake b/cmake/modules/FindTexturePacker.cmake
new file mode 100644
index 0000000..aa6fd3a
--- /dev/null
+++ b/cmake/modules/FindTexturePacker.cmake
@@ -0,0 +1,41 @@
+#.rst:
+# FindTexturePacker
+# -----------------
+# Finds the TexturePacker
+#
+# If WITH_TEXTUREPACKER is defined and points to a directory,
+# this path will be used to search for the Texturepacker binary
+#
+#
+# This will define the following (imported) targets::
+#
+#   TexturePacker::TexturePacker   - The TexturePacker executable
+
+if(NOT TARGET TexturePacker::TexturePacker)
+  if(KODI_DEPENDSBUILD)
+    add_executable(TexturePacker::TexturePacker IMPORTED GLOBAL)
+    set_target_properties(TexturePacker::TexturePacker PROPERTIES
+                                                       IMPORTED_LOCATION "${NATIVEPREFIX}/bin/TexturePacker")
+  elseif(WIN32)
+    add_executable(TexturePacker::TexturePacker IMPORTED GLOBAL)
+    set_target_properties(TexturePacker::TexturePacker PROPERTIES
+                                                       IMPORTED_LOCATION "${CMAKE_SOURCE_DIR}/tools/TexturePacker/TexturePacker.exe")
+  else()
+    if(WITH_TEXTUREPACKER)
+      get_filename_component(_tppath ${WITH_TEXTUREPACKER} ABSOLUTE)
+      find_program(TEXTUREPACKER_EXECUTABLE TexturePacker PATHS ${_tppath})
+
+      include(FindPackageHandleStandardArgs)
+      find_package_handle_standard_args(TexturePacker DEFAULT_MSG TEXTUREPACKER_EXECUTABLE)
+      if(TEXTUREPACKER_FOUND)
+        add_executable(TexturePacker::TexturePacker IMPORTED GLOBAL)
+        set_target_properties(TexturePacker::TexturePacker PROPERTIES
+                                                           IMPORTED_LOCATION "${TEXTUREPACKER_EXECUTABLE}")
+      endif()
+      mark_as_advanced(TEXTUREPACKER)
+    else()
+      add_subdirectory(${CMAKE_SOURCE_DIR}/tools/depends/native/TexturePacker build/texturepacker)
+      add_executable(TexturePacker::TexturePacker ALIAS TexturePacker)
+    endif()
+  endif()
+endif()
-- 
cgit v1.2.3