From 9fc8b732737f139d3e466510d75668ab45578960 Mon Sep 17 00:00:00 2001
From: manuel <manuel@mausz.at>
Date: Tue, 8 Mar 2016 21:02:53 +0100
Subject: sync with upstream

---
 project/cmake/modules/FindTagLib.cmake | 62 ++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 project/cmake/modules/FindTagLib.cmake

(limited to 'project/cmake/modules/FindTagLib.cmake')

diff --git a/project/cmake/modules/FindTagLib.cmake b/project/cmake/modules/FindTagLib.cmake
new file mode 100644
index 0000000..b515e81
--- /dev/null
+++ b/project/cmake/modules/FindTagLib.cmake
@@ -0,0 +1,62 @@
+#.rst:
+# FindTagLib
+# ----------
+# Finds the TagLib library
+#
+# This will will define the following variables::
+#
+# TAGLIB_FOUND - system has TagLib
+# TAGLIB_INCLUDE_DIRS - the TagLib include directory
+# TAGLIB_LIBRARIES - the TagLib libraries
+#
+# and the following imported targets::
+#
+#   TagLib::TagLib   - The TagLib library
+
+if(PKG_CONFIG_FOUND)
+  pkg_check_modules(PC_TAGLIB taglib>=1.8.0 QUIET)
+endif()
+
+find_path(TAGLIB_INCLUDE_DIR taglib/tag.h
+                             PATHS ${PC_TAGLIB_INCLUDEDIR})
+find_library(TAGLIB_LIBRARY_RELEASE NAMES tag
+                                    PATH_SUFFIXES ${CONFIGURATION_LIBDIR_RELEASE}
+                                    PATHS ${PC_TAGLIB_LIBDIR})
+find_library(TAGLIB_LIBRARY_DEBUG NAMES tag
+                                  PATH_SUFFIXES ${CONFIGURATION_LIBDIR_DEBUG}
+                                  PATHS ${PC_TAGLIB_LIBDIR})
+set(TAGLIB_VERSION ${PC_TAGLIB_VERSION})
+
+include(SelectLibraryConfigurations)
+select_library_configurations(TAGLIB)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(TAGLIB
+                                  REQUIRED_VARS TAGLIB_LIBRARY TAGLIB_INCLUDE_DIR
+                                  VERSION_VAR TAGLIB_VERSION)
+
+if(TAGLIB_FOUND)
+  set(TAGLIB_LIBRARIES ${TAGLIB_LIBRARY})
+
+  # Workaround broken .pc file
+  list(APPEND TAGLIB_LIBRARIES ${PC_TAGLIB_ZLIB_LIBRARIES})
+
+  set(TAGLIB_INCLUDE_DIRS ${TAGLIB_INCLUDE_DIR})
+  if(NOT TARGET TagLib::TagLib)
+    add_library(TagLib::TagLib UNKNOWN IMPORTED)
+    if(TAGLIB_LIBRARY_RELEASE)
+      set_target_properties(TagLib::TagLib PROPERTIES
+                                           IMPORTED_CONFIGURATIONS RELEASE
+                                           IMPORTED_LOCATION "${TAGLIB_LIBRARY_RELEASE}")
+    endif()
+    if(TAGLIB_LIBRARY_DEBUG)
+      set_target_properties(TagLib::TagLib PROPERTIES
+                                           IMPORTED_CONFIGURATIONS DEBUG
+                                           IMPORTED_LOCATION "${TAGLIB_LIBRARY_DEBUG}")
+    endif()
+    set_target_properties(TagLib::TagLib PROPERTIES
+                                         INTERFACE_INCLUDE_DIRECTORIES "${TAGLIB_INCLUDE_DIR}")
+  endif()
+endif()
+
+mark_as_advanced(TAGLIB_INCLUDE_DIR TAGLIB_LIBRARY)
-- 
cgit v1.2.3