From 9fc8b732737f139d3e466510d75668ab45578960 Mon Sep 17 00:00:00 2001
From: manuel <manuel@mausz.at>
Date: Tue, 8 Mar 2016 21:02:53 +0100
Subject: sync with upstream

---
 project/cmake/modules/FindUUID.cmake | 43 ++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 project/cmake/modules/FindUUID.cmake

(limited to 'project/cmake/modules/FindUUID.cmake')

diff --git a/project/cmake/modules/FindUUID.cmake b/project/cmake/modules/FindUUID.cmake
new file mode 100644
index 0000000..173fac2
--- /dev/null
+++ b/project/cmake/modules/FindUUID.cmake
@@ -0,0 +1,43 @@
+#.rst:
+# FindUUID
+# --------
+# Finds the libuuid library
+#
+# This will will define the following variables::
+#
+# UUID_FOUND - system has libuuid
+# UUID_INCLUDE_DIRS - the libuuid include directory
+# UUID_LIBRARIES - the libuuid libraries
+#
+# and the following imported targets::
+#
+#   UUID::UUID   - The libuuid library
+
+if(PKG_CONFIG_FOUND)
+  pkg_check_modules(PC_UUID uuid QUIET)
+endif()
+
+find_path(UUID_INCLUDE_DIR uuid/uuid.h
+                           PATHS ${PC_UUID_INCLUDEDIR})
+find_library(UUID_LIBRARY uuid
+                          PATHS ${PC_UUID_LIBRARY})
+set(UUID_VERSION ${PC_UUID_VERSION})
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(UUID
+                                  REQUIRED_VARS UUID_LIBRARY UUID_INCLUDE_DIR
+                                  VERSION_VAR UUID_VERSION)
+
+if(UUID_FOUND)
+  set(UUID_LIBRARIES ${UUID_LIBRARY})
+  set(UUID_INCLUDE_DIRS ${UUID_INCLUDE_DIR})
+
+  if(NOT TARGET UUID::UUID)
+    add_library(UUID::UUID UNKNOWN IMPORTED)
+    set_target_properties(UUID::UUID PROPERTIES
+                                     IMPORTED_LOCATION "${UUID_LIBRARY}"
+                                     INTERFACE_INCLUDE_DIRECTORIES "${UUID_INCLUDE_DIR}")
+  endif()
+endif()
+
+mark_as_advanced(UUID_INCLUDE_DIR UUID_LIBRARY)
-- 
cgit v1.2.3