From 4f670845ff9ab6c48bcb5f7bf4d4ef6dc3c3064b Mon Sep 17 00:00:00 2001
From: manuel <manuel@mausz.at>
Date: Tue, 27 Mar 2012 11:51:08 +0200
Subject: reorganize file structure to match the upstream requirements

---
 pintos-progos/threads/switch.S | 65 ------------------------------------------
 1 file changed, 65 deletions(-)
 delete mode 100644 pintos-progos/threads/switch.S

(limited to 'pintos-progos/threads/switch.S')

diff --git a/pintos-progos/threads/switch.S b/pintos-progos/threads/switch.S
deleted file mode 100644
index feca86c..0000000
--- a/pintos-progos/threads/switch.S
+++ /dev/null
@@ -1,65 +0,0 @@
-#include "threads/switch.h"
-
-#### struct thread *switch_threads (struct thread *cur, struct thread *next);
-####
-#### Switches from CUR, which must be the running thread, to NEXT,
-#### which must also be running switch_threads(), returning CUR in
-#### NEXT's context.
-####
-#### This function works by assuming that the thread we're switching
-#### into is also running switch_threads().  Thus, all it has to do is
-#### preserve a few registers on the stack, then switch stacks and
-#### restore the registers.  As part of switching stacks we record the
-#### current stack pointer in CUR's thread structure.
-
-.globl switch_threads
-.func switch_threads
-switch_threads:
-	# Save caller's register state.
-	#
-	# Note that the SVR4 ABI allows us to destroy %eax, %ecx, %edx,
-	# but requires us to preserve %ebx, %ebp, %esi, %edi.  See
-	# [SysV-ABI-386] pages 3-11 and 3-12 for details.
-	#
-	# This stack frame must match the one set up by thread_create()
-	# in size.
-	pushl %ebx
-	pushl %ebp
-	pushl %esi
-	pushl %edi
-
-	# Get offsetof (struct thread, stack).
-.globl thread_stack_ofs
-	mov thread_stack_ofs, %edx
-
-	# Save current stack pointer to old thread's stack, if any.
-	movl SWITCH_CUR(%esp), %eax
-	movl %esp, (%eax,%edx,1)
-
-	# Restore stack pointer from new thread's stack.
-	movl SWITCH_NEXT(%esp), %ecx
-	movl (%ecx,%edx,1), %esp
-
-	# Restore caller's register state.
-	popl %edi
-	popl %esi
-	popl %ebp
-	popl %ebx
-        ret
-.endfunc
-
-.globl switch_entry
-.func switch_entry
-switch_entry:
-	# Discard switch_threads() arguments.
-	addl $8, %esp
-
-	# Call thread_schedule_tail(prev).
-	pushl %eax
-.globl thread_schedule_tail
-	call thread_schedule_tail
-	addl $4, %esp
-
-	# Start thread proper.
-	ret
-.endfunc
-- 
cgit v1.2.3