13 files changed, 268 insertions, 0 deletions

diff --git a/project/cmake/addons/depends/CMakeLists.txt b/project/cmake/addons/depends/CMakeLists.txt
new file mode 100644
index 0000000..760acf4
--- /dev/null
+++ b/project/cmake/addons/depends/CMakeLists.txt
@@ -0,0 +1,42 @@
+project(kodi-addons-depends)
+
+cmake_minimum_required(VERSION 2.8)
+
+list(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR})
+
+if(NOT CMAKE_BUILD_TYPE)
+  set(CMAKE_BUILD_TYPE Release)
+endif()
+
+if(NOT CORE_SYSTEM_NAME)
+  string(TOLOWER ${CMAKE_SYSTEM_NAME} CORE_SYSTEM_NAME)
+endif()
+
+include(ExternalProject)
+
+if(NOT DEPENDS_PATH)
+  set(DEPENDS_PATH ${PROJECT_SOURCE_DIR}/../build/depends)
+else()
+  file(TO_CMAKE_PATH "${DEPENDS_PATH}" DEPENDS_PATH)
+endif()
+get_filename_component(DEPENDS_PATH "${DEPENDS_PATH}" ABSOLUTE)
+list(APPEND CMAKE_PREFIX_PATH ${DEPENDS_PATH})
+
+if(NOT BUILD_DIR)
+    set(BUILD_DIR "${CMAKE_BINARY_DIR}/build")
+else()
+  file(TO_CMAKE_PATH "${BUILD_DIR}" BUILD_DIR)
+endif()
+get_filename_component(BUILD_DIR "${BUILD_DIR}" ABSOLUTE)
+
+## use add_addon_depends to handle the cmake based dependencies
+include(${APP_ROOT}/project/cmake/scripts/common/handle-depends.cmake)
+add_addon_depends(depends "${PROJECT_SOURCE_DIR}")
+
+## if there's a platform-specific sub-directory containing a CMakeLists.txt, add it to the build as well
+if(EXISTS ${PROJECT_SOURCE_DIR}/${CORE_SYSTEM_NAME}/CMakeLists.txt)
+  message(STATUS "Processing ${CORE_SYSTEM_NAME}")
+  add_subdirectory(${CORE_SYSTEM_NAME})
+else()
+  message(STATUS "No platform specific file ${PROJECT_SOURCE_DIR}/${CORE_SYSTEM_NAME}/CMakeLists.txt found")
+endif()
diff --git a/project/cmake/addons/depends/README b/project/cmake/addons/depends/README
new file mode 100644
index 0000000..66e924a
--- /dev/null
+++ b/project/cmake/addons/depends/README
@@ -0,0 +1,61 @@
+KODI ADDON DEPENDENCIES
+=======================
+This directory contains the cmake-based buildsystem for addon dependencies. It
+looks into the "common" and the "<platform>/cmake" sub-directories and parses
+all *.txt files recursively. Each dependency must have its own <dependency>.txt
+file (either in the main sub-directory or in a separate subdirectory of the main
+subdirectory) which must follow one of the defined formats:
+  * an empty file means that no extra downloads are necessary
+  * <dependency>
+  * <dependency> <url>
+  * <dependency> <git-url> <git-revision>
+where
+  * <dependency> must be identical to the filename
+  * <url> must be the URL to an archive that is downloaded and extracted.
+  * <git-url> must be the URL of the git repository containing the
+    dependency.
+  * <git-revision> must be a valid git tag/branch/commit in the dependency's git
+    repository which will be used for the build.
+
+Reserved filenames (for additional information on how to build a dependency)
+are:
+  * CMakeLists.txt: build instructions for the dependency
+  * install.txt: instructions on how to install the dependency's built files
+  * noinstall.txt: no installation step required (content is ignored)
+  * flags.txt: additional build flags
+  * deps.txt: whitespace separated list of dependencies of this dependency
+
+The buildsystem uses the following variables (which can be passed into it when
+executing cmake with the -D<variable-name>=<value> option) to e.g. access
+specific paths:
+  * CMAKE_BUILD_TYPE specifies the type of the build. This can be either "Debug"
+    or "Release" (default is "Release").
+  * CMAKE_TOOLCHAIN_FILE can be used to pass a toolchain file into the add-on
+    builds.
+  * CORE_SYSTEM_NAME is the name of the platform (e.g. "linux" or "android") in
+    lower-case (defaults to lowercase(CMAKE_SYSTEM_NAME)).
+  * APP_ROOT points to the root directory of the project (default is the
+    absolute representation of ../../.. starting from this directory).
+  * DEPENDS_PATH points to the directory where the built dependencies
+    (their include and library file) will be installed to.
+  * ARCH_DEFINES specifies the platform-specific C/C++ preprocessor defines
+    (defaults to empty).
+  * DEPENDS_TO_BUILD is a quoted, space delimited list of <dependency>s that
+    you want to build (default is "all").
+
+To trigger the cmake-based buildsystem the following command must be executed
+with <path> being the path to this directory (absolute or relative, allowing for
+in-source and out-of-source builds).
+
+  cmake <path> -G <generator>
+
+cmake supports multiple generators, see
+http://www.cmake.org/cmake/help/v2.8.8/cmake.html#section_Generators for a list.
+
+In case of additional options the call might look like this
+
+  cmake <path> [-G <generator>] \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DAPP_ROOT="<path-to-project-root>" \
+        -DARCH_DEFINES="-DTARGET_LINUX" \
+        -DCMAKE_INSTALL_PREFIX="<path-to-install-directory"
diff --git a/project/cmake/addons/depends/common/kodi-platform/deps.txt b/project/cmake/addons/depends/common/kodi-platform/deps.txt
new file mode 100644
index 0000000..f0e8246
--- /dev/null
+++ b/project/cmake/addons/depends/common/kodi-platform/deps.txt
@@ -0,0 +1,2 @@
+kodi
+tinyxml
\ No newline at end of file
diff --git a/project/cmake/addons/depends/common/kodi-platform/kodi-platform.txt b/project/cmake/addons/depends/common/kodi-platform/kodi-platform.txt
new file mode 100644
index 0000000..fb6916a
--- /dev/null
+++ b/project/cmake/addons/depends/common/kodi-platform/kodi-platform.txt
@@ -0,0 +1 @@
+kodi-platform https://github.com/xbmc/kodi-platform 68315f0
diff --git a/project/cmake/addons/depends/common/tinyxml/CMakeLists.txt b/project/cmake/addons/depends/common/tinyxml/CMakeLists.txt
new file mode 100644
index 0000000..5468bfb
--- /dev/null
+++ b/project/cmake/addons/depends/common/tinyxml/CMakeLists.txt
@@ -0,0 +1,23 @@
+project(tinyxml)
+
+cmake_minimum_required(VERSION 2.8)
+
+set(SOURCES src/tinystr.cpp
+            src/tinyxml.cpp
+            src/tinyxmlerror.cpp
+            src/tinyxmlparser.cpp)
+
+if(WIN32)
+  add_definitions(-DWIN32 -D_LIB)
+endif()
+add_definitions(-DTIXML_USE_STL)
+
+add_library(tinyxml ${SOURCES})
+
+include_directories(${PROJECT_SOURCE_DIR}/include)
+
+set(HEADERS ${PROJECT_SOURCE_DIR}/include/tinystr.h
+            ${PROJECT_SOURCE_DIR}/include/tinyxml.h)
+
+install(FILES ${HEADERS} DESTINATION ${CMAKE_INSTALL_PREFIX}/include)
+install(TARGETS tinyxml DESTINATION ${CMAKE_INSTALL_PREFIX}/lib)
diff --git a/project/cmake/addons/depends/common/tinyxml/tinyxml.txt b/project/cmake/addons/depends/common/tinyxml/tinyxml.txt
new file mode 100644
index 0000000..456b0c5
--- /dev/null
+++ b/project/cmake/addons/depends/common/tinyxml/tinyxml.txt
@@ -0,0 +1 @@
+tinyxml http://mirrors.xbmc.org/build-deps/sources/tinyxml-2.6.2_2.tar.gz
diff --git a/project/cmake/addons/depends/windows/CMakeLists.txt b/project/cmake/addons/depends/windows/CMakeLists.txt
new file mode 100644
index 0000000..4480f1e
--- /dev/null
+++ b/project/cmake/addons/depends/windows/CMakeLists.txt
@@ -0,0 +1,55 @@
+project(kodi-addons-depends-windows)
+
+cmake_minimum_required(VERSION 2.8)
+
+list(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR})
+
+if(NOT CMAKE_BUILD_TYPE)
+  set(CMAKE_BUILD_TYPE Release)
+endif()
+
+include(ExternalProject)
+
+if(NOT DEPENDS_PATH)
+  message(FATAL_ERROR "DEPENDS_PATH (${DEPENDS_PATH}) is not a valid target directory.")
+else()
+  file(TO_CMAKE_PATH "${DEPENDS_PATH}" DEPENDS_PATH)
+endif()
+get_filename_component(DEPENDS_PATH "${DEPENDS_PATH}" ABSOLUTE)
+list(APPEND CMAKE_PREFIX_PATH ${DEPENDS_PATH})
+
+if(NOT DEPENDS_TO_BUILD)
+  set(DEPENDS_TO_BUILD "all")
+endif()
+
+function(add_internal id url inputfile)
+  externalproject_add(${id}
+                      URL ${url}
+                      PREFIX build/${id}
+                      CONFIGURE_COMMAND ""
+                      BUILD_COMMAND ""
+                      INSTALL_COMMAND ${CMAKE_COMMAND}
+                                      -DINPUTDIR=${PROJECT_BINARY_DIR}/build/${id}/src/${id}
+                                      -DINPUTFILE=${inputfile}
+                                      -DDESTDIR=${DEPENDS_PATH}
+                                      -P ${PROJECT_SOURCE_DIR}/install.cmake
+                     )
+endfunction()
+
+#find_package(7Zip REQUIRED)
+
+file(GLOB_RECURSE download_input_files prebuilt/*.txt)
+foreach(file ${download_input_files})
+  if(NOT file MATCHES install.txt)
+    file(STRINGS ${file} def)
+    get_filename_component(dir ${file} PATH)
+    separate_arguments(def)
+    list(GET def 0 id)
+
+    list(FIND DEPENDS_TO_BUILD ${id} idx)
+    if(idx GREATER -1 OR DEPENDS_TO_BUILD STREQUAL "all")
+      list(GET def 1 url)
+      add_internal(${id} ${url} ${dir}/install.txt)
+    endif()
+  endif()
+endforeach()
diff --git a/project/cmake/addons/depends/windows/Find7Zip.cmake b/project/cmake/addons/depends/windows/Find7Zip.cmake
new file mode 100644
index 0000000..82b0902
--- /dev/null
+++ b/project/cmake/addons/depends/windows/Find7Zip.cmake
@@ -0,0 +1,7 @@
+find_program(7ZIP_EXECUTABLE NAMES 7z.exe
+             HINTS PATHS "c:/Program Files/7-Zip")
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(7Zip DEFAULT_MSG 7ZIP_EXECUTABLE)
+
+mark_as_advanced(7ZIP_EXECUTABLE)
diff --git a/project/cmake/addons/depends/windows/README b/project/cmake/addons/depends/windows/README
new file mode 100644
index 0000000..67dc594
--- /dev/null
+++ b/project/cmake/addons/depends/windows/README
@@ -0,0 +1,19 @@
+KODI WIN32 ADDON DEPENDENCIES
+=============================
+This directory contains the cmake-based buildsystem for dependencies (currently
+only prebuilt) used by one or multiple addons. The buildsystem looks into the
+"prebuilt" sub-directory, downloads all the specified dependencies, extracts
+them and places them into the "depends" sub-directory.
+
+To trigger the cmake-based buildsystem the following command must be executed
+with <path> being the path to this directory (absolute or relative, allowing for
+in-source and out-of-source builds).
+
+  cmake <path> [-G <generator>]
+
+cmake supports multiple generators, see
+http://www.cmake.org/cmake/help/v2.8.8/cmake.html#section_Generators for a list.
+For win32 builds one of the "Visual Studio XX" or the "NMake Makefiles"
+generators is preferred. For the "NMake Makefiles" generator to work the above
+command must be called from an environment prepared for VC++ builds (see
+http://msdn.microsoft.com/en-us/library/f2ccy3wt.aspx).
diff --git a/project/cmake/addons/depends/windows/extract-7z.cmake b/project/cmake/addons/depends/windows/extract-7z.cmake
new file mode 100644
index 0000000..95a2672
--- /dev/null
+++ b/project/cmake/addons/depends/windows/extract-7z.cmake
@@ -0,0 +1,10 @@
+get_filename_component(file ${URL} NAME)
+file(DOWNLOAD ${URL} ${DEST}/${file})
+execute_process(COMMAND ${7ZIP_EXECUTABLE} -y x ${DEST}/${file}
+                WORKING_DIRECTORY ${DESTDIR})
+if(${file} MATCHES .tar)
+  string(REPLACE ".7z" "" tarball ${file})
+  string(REPLACE ".lzma" "" tarball ${file})
+  execute_process(COMMAND ${7ZIP_EXECUTABLE} -y x ${DESTDIR}/${tarball}
+                  WORKING_DIRECTORY ${DESTDIR})
+endif()
diff --git a/project/cmake/addons/depends/windows/extract-direct.cmake b/project/cmake/addons/depends/windows/extract-direct.cmake
new file mode 100644
index 0000000..13cb74f
--- /dev/null
+++ b/project/cmake/addons/depends/windows/extract-direct.cmake
@@ -0,0 +1,2 @@
+get_filename_component(file ${URL} NAME)
+file(DOWNLOAD ${URL} ${DEST}/${file})
diff --git a/project/cmake/addons/depends/windows/install.cmake b/project/cmake/addons/depends/windows/install.cmake
new file mode 100644
index 0000000..9a3adbb
--- /dev/null
+++ b/project/cmake/addons/depends/windows/install.cmake
@@ -0,0 +1,24 @@
+if(EXISTS "${INPUTFILE}")
+  # if there's an input file we use it to determine which files to copy where
+  file(STRINGS ${INPUTFILE} FILES)
+  string(REPLACE "\n" ";" FILES "${FILES}")
+  foreach(file ${FILES})
+    string(REPLACE " " ";" file "${file}")
+    list(GET file 0 dir)
+    list(GET file 1 dest)
+    list(LENGTH file deflength)
+    if(deflength GREATER 2)
+      list(GET file 2 copy)
+    endif()
+    file(GLOB files ${INPUTDIR}/${dir})
+    foreach(instfile ${files})
+      file(COPY ${instfile} DESTINATION ${DESTDIR}/${dest})
+      if(copy)
+        file(COPY ${instfile} DESTINATION ${DESTDIR}/${copy})
+      endif()
+    endforeach()
+  endforeach()
+else()
+  # otherwise we assume that the content of the extracted archive is already well-formed and can just be copied
+  file(COPY ${INPUTDIR}/${dir} DESTINATION ${DESTDIR})
+endif()
\ No newline at end of file
diff --git a/project/cmake/addons/depends/windows/prebuilt/README b/project/cmake/addons/depends/windows/prebuilt/README
new file mode 100644
index 0000000..a0c70d6
--- /dev/null
+++ b/project/cmake/addons/depends/windows/prebuilt/README
@@ -0,0 +1,21 @@
+KODI WIN32 PREBUILT ADDON DEPENDENCIES
+======================================
+This directory contains a file or sub-directory for every prebuilt dependency
+used by one of the addons being built. There are two different modes supported.
+Both include a file named <library-id>.txt which must follow the defined format
+  <library-id> <download-url>
+
+If the archive, which the <download-url> points at, contains
+ * only the necessary files and in the proper directory structure (i.e. an
+   "include" and a "lib" directory) then the file must be put into this
+   directory and nothing else is needed.
+ * unnecessary files and/or does not follow the defined directory structure
+   (i.e. an "include" and a "lib" directory) then the file must be put into a
+   sub-directory named <library-id>. Furthermore an additional file called
+   "install.txt" must be placed in that sub-directory. install.txt contains a
+   line for every path/directory/file with a destination where it must be copied
+   to. It must follow the defined format
+     <source> <destination> [<copy-destination>]
+   where <source> must be an existing file, directory or a path containing
+   wildcards, <destination> and the optional <copy-destination> must be existing
+   directories.