7 files changed, 169 insertions, 9 deletions

diff --git a/project/cmake/scripts/android/archsetup.cmake b/project/cmake/scripts/android/ArchSetup.cmake
index 86c0f6a..281f94f 100644
--- a/project/cmake/scripts/android/archsetup.cmake
+++ b/project/cmake/scripts/android/ArchSetup.cmake
@@ -1,5 +1,7 @@
 if(NOT CMAKE_TOOLCHAIN_FILE)
   message(FATAL_ERROR "CMAKE_TOOLCHAIN_FILE required for android. See ${PROJECT_SOURCE_DIR}/README.md")
+elseif(NOT SDK_PLATFORM)
+  message(FATAL_ERROR "Toolchain did not define SDK_PLATFORM. Possibly outdated depends.")
 endif()
 
 set(ARCH_DEFINES -DTARGET_POSIX -DTARGET_LINUX -D_LINUX -DTARGET_ANDROID)
@@ -10,9 +12,13 @@ if(WITH_ARCH)
   set(ARCH ${WITH_ARCH})
 else()
   if(CPU STREQUAL armeabi-v7a)
-    set(ARCH arm-linux-androideabi)
+    set(ARCH arm)
+    set(NEON True)
+  elseif(CPU STREQUAL arm64-v8a)
+    set(ARCH aarch64)
   elseif(CPU STREQUAL i686)
-    set(ARCH i686-linux-android)
+    set(ARCH i486-linux)
+    set(NEON False)
   else()
     message(SEND_ERROR "Unknown CPU: ${CPU}")
   endif()
@@ -21,10 +27,9 @@ endif()
 set(FFMPEG_OPTS --enable-cross-compile --cpu=cortex-a9 --arch=arm --target-os=linux --enable-neon
                 --disable-vdpau --cc=${CMAKE_C_COMPILER} --host-cc=${CMAKE_C_COMPILER}
                 --strip=${CMAKE_STRIP})
-set(ENABLE_SDL OFF)
-set(ENABLE_X11 OFF)
-set(ENABLE_EGL ON)
-set(ENABLE_AML ON)
-set(ENABLE_OPTICAL OFF)
+set(ENABLE_SDL OFF CACHE BOOL "" FORCE)
+set(ENABLE_X11 OFF CACHE BOOL "" FORCE)
+set(ENABLE_AML OFF CACHE BOOL "" FORCE)
+set(ENABLE_OPTICAL OFF CACHE BOOL "" FORCE)
 
 list(APPEND DEPLIBS android log jnigraphics)
diff --git a/project/cmake/scripts/android/Install.cmake b/project/cmake/scripts/android/Install.cmake
new file mode 100644
index 0000000..5c66f41
--- /dev/null
+++ b/project/cmake/scripts/android/Install.cmake
@@ -0,0 +1,123 @@
+# Android packaging
+
+find_program(AAPT_EXECUTABLE aapt PATHS ${SDK_BUILDTOOLS_PATH})
+if(NOT AAPT_EXECUTABLE)
+  message(FATAL_ERROR "Could NOT find aapt executable")
+endif()
+find_program(DX_EXECUTABLE dx PATHS ${SDK_BUILDTOOLS_PATH})
+if(NOT DX_EXECUTABLE)
+  message(FATAL_ERROR "Could NOT find dx executable")
+endif()
+find_program(ZIPALIGN_EXECUTABLE zipalign PATHS ${SDK_BUILDTOOLS_PATH})
+if(NOT ZIPALIGN_EXECUTABLE)
+  message(FATAL_ERROR "Could NOT find zipalign executable")
+endif()
+
+# Configure files into packaging environment.
+configure_file(${CORE_SOURCE_DIR}/tools/android/packaging/Makefile.in
+               ${CMAKE_BINARY_DIR}/tools/android/packaging/Makefile @ONLY)
+configure_file(${CORE_SOURCE_DIR}/tools/android/packaging/apksign
+               ${CMAKE_BINARY_DIR}/tools/android/packaging/apksign COPYONLY)
+configure_file(${CORE_SOURCE_DIR}/tools/android/packaging/make_symbols.sh
+               ${CMAKE_BINARY_DIR}/tools/android/packaging/make_symbols.sh COPYONLY)
+file(WRITE ${CMAKE_BINARY_DIR}/tools/depends/Makefile.include
+     "$(PREFIX)/lib/${APP_NAME_LC}/lib${APP_NAME_LC}.so: ;\n")
+
+set(package_files strings.xml
+                  activity_main.xml
+                  AndroidManifest.xml
+                  src/org/xbmc/kodi/XBMCOnAudioFocusChangeListener.java
+                  src/org/xbmc/kodi/XBMCInputDeviceListener.java
+                  src/org/xbmc/kodi/Main.java
+                  src/org/xbmc/kodi/XBMCSettingsContentObserver.java
+                  src/org/xbmc/kodi/XBMCOnFrameAvailableListener.java
+                  src/org/xbmc/kodi/XBMCVideoView.java
+                  src/org/xbmc/kodi/Splash.java
+                  src/org/xbmc/kodi/XBMCBroadcastReceiver.java)
+foreach(file IN LISTS package_files)
+  configure_file(${CORE_SOURCE_DIR}/tools/android/packaging/xbmc/${file}.in
+                 ${CMAKE_BINARY_DIR}/tools/android/packaging/xbmc/${file} @ONLY)
+endforeach()
+
+# Copy files to the location expected by the Android packaging scripts.
+add_custom_target(bundle
+    COMMAND ${CMAKE_COMMAND} -E copy_directory ${CORE_SOURCE_DIR}/tools/android/packaging/media
+                                               ${CMAKE_BINARY_DIR}/tools/android/packaging/media
+    COMMAND ${CMAKE_COMMAND} -E copy_directory ${CORE_SOURCE_DIR}/tools/android/packaging/xbmc/res
+                                               ${CMAKE_BINARY_DIR}/tools/android/packaging/xbmc/res
+    COMMAND ${CMAKE_COMMAND} -E copy_directory ${DEPENDS_PATH}/lib/python2.7 ${libdir}/python2.7
+    COMMAND ${CMAKE_COMMAND} -E copy_directory ${DEPENDS_PATH}/share/${APP_NAME_LC} ${datadir}/${APP_NAME_LC}
+    COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:${APP_NAME_LC}>
+                                     ${libdir}/${APP_NAME_LC}/$<TARGET_FILE_NAME:${APP_NAME_LC}>)
+add_dependencies(bundle ${APP_NAME_LC})
+
+# This function is used to prepare a prefix expected by the Android packaging
+# scripts. It creates a bundle_files command that is added to the bundle target.
+function(add_bundle_file file destination relative)
+  if(NOT TARGET bundle_files)
+    file(REMOVE ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/BundleFiles.cmake)
+    add_custom_target(bundle_files COMMAND ${CMAKE_COMMAND} -P ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/BundleFiles.cmake)
+    add_dependencies(bundle bundle_files)
+  endif()
+
+  string(REPLACE "${relative}/" "" outfile ${file})
+  get_filename_component(file ${file} REALPATH)
+  get_filename_component(outdir ${outfile} DIRECTORY)
+  file(APPEND ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/BundleFiles.cmake
+       "file(COPY \"${file}\" DESTINATION \"${destination}/${outdir}\")\n")
+  if(file MATCHES "\\.so\\..+$")
+    get_filename_component(srcfile "${file}" NAME)
+    string(REGEX REPLACE "\\.so\\..+$" "\.so" destfile ${srcfile})
+    file(APPEND ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/BundleFiles.cmake
+         "file(RENAME \"${destination}/${outdir}/${srcfile}\" \"${destination}/${outdir}/${destfile}\")\n")
+  endif()
+endfunction()
+
+# Copy files into prefix
+foreach(file IN LISTS XBT_FILES install_data)
+  string(REPLACE "${CMAKE_BINARY_DIR}/" "" file ${file})
+  add_bundle_file(${CMAKE_BINARY_DIR}/${file} ${datarootdir}/${APP_NAME_LC} ${CMAKE_BINARY_DIR})
+endforeach()
+
+foreach(library IN LISTS LIBRARY_FILES)
+  add_bundle_file(${library} ${libdir}/${APP_NAME_LC} ${CMAKE_BINARY_DIR})
+endforeach()
+
+foreach(lib IN LISTS required_dyload dyload_optional ITEMS Shairplay)
+  string(TOUPPER ${lib} lib_up)
+  set(lib_so ${${lib_up}_SONAME})
+  if(lib_so AND EXISTS ${DEPENDS_PATH}/lib/${lib_so})
+    add_bundle_file(${DEPENDS_PATH}/lib/${lib_so} ${libdir} "")
+  endif()
+endforeach()
+add_bundle_file(${SMBCLIENT_LIBRARY} ${libdir} "")
+add_bundle_file(${DEPENDS_PATH}/lib/librtmp.so ${libdir} "")
+
+# Main targets from Makefile.in
+if(CPU MATCHES i686)
+  set(CPU x86)
+  set(ARCH x86)
+endif()
+foreach(target apk obb apk-unsigned apk-obb apk-obb-unsigned apk-noobb apk-clean apk-sign)
+  add_custom_target(${target}
+      COMMAND PATH=${NATIVEPREFIX}/bin:$ENV{PATH} ${CMAKE_MAKE_PROGRAM}
+              -C ${CMAKE_BINARY_DIR}/tools/android/packaging
+              CORE_SOURCE_DIR=${CORE_SOURCE_DIR}
+              CC=${CMAKE_C_COMPILER}
+              CPU=${CPU}
+              ARCH=${ARCH}
+              PREFIX=${prefix}
+              NDKROOT=${NDKROOT}
+              SDKROOT=${SDKROOT}
+              SDK_PLATFORM=${SDK_PLATFORM}
+              STRIP=${CMAKE_STRIP}
+              AAPT=${AAPT_EXECUTABLE}
+              DX=${DX_EXECUTABLE}
+              ZIPALIGN=${ZIPALIGN_EXECUTABLE}
+              ${target}
+      WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/tools/android/packaging
+  )
+  if(NOT target STREQUAL apk-clean)
+    add_dependencies(${target} bundle)
+  endif()
+endforeach()
diff --git a/project/cmake/scripts/android/Macros.cmake b/project/cmake/scripts/android/Macros.cmake
new file mode 120000
index 0000000..2fdbb25
--- /dev/null
+++ b/project/cmake/scripts/android/Macros.cmake
@@ -0,0 +1 @@
+../linux/Macros.cmake
\ No newline at end of file
diff --git a/project/cmake/scripts/android/PathSetup.cmake b/project/cmake/scripts/android/PathSetup.cmake
new file mode 100644
index 0000000..69de883
--- /dev/null
+++ b/project/cmake/scripts/android/PathSetup.cmake
@@ -0,0 +1,33 @@
+if(NOT prefix)
+  set(prefix ${CMAKE_BINARY_DIR}/install)
+endif()
+set(CMAKE_INSTALL_PREFIX ${prefix})
+if(NOT exec_prefix)
+  set(exec_prefix ${prefix})
+endif()
+if(NOT libdir)
+  set(libdir ${prefix}/lib)
+endif()
+if(NOT bindir)
+  set(bindir ${prefix}/bin)
+endif()
+if(NOT includedir)
+  set(includedir ${prefix}/include)
+endif()
+if(NOT datarootdir)
+  set(datarootdir ${prefix}/share)
+endif()
+if(NOT datadir)
+  set(datadir ${datarootdir})
+endif()
+
+list(APPEND final_message "-- PATH config --")
+list(APPEND final_message "Prefix: ${prefix}")
+list(APPEND final_message "Libdir: ${libdir}")
+list(APPEND final_message "Bindir: ${bindir}")
+list(APPEND final_message "Includedir: ${includedir}")
+list(APPEND final_message "Datarootdir: ${datarootdir}")
+list(APPEND final_message "Datadir: ${datadir}")
+
+set(PATH_DEFINES -DBIN_INSTALL_PATH=\"${libdir}/kodi\"
+                   -DINSTALL_PATH=\"${datarootdir}/kodi\")
diff --git a/project/cmake/scripts/android/install.cmake b/project/cmake/scripts/android/install.cmake
deleted file mode 100644
index e69de29..0000000
--- a/project/cmake/scripts/android/install.cmake
+++ /dev/null
diff --git a/project/cmake/scripts/android/macros.cmake b/project/cmake/scripts/android/macros.cmake
deleted file mode 120000
index 28c77ca..0000000
--- a/project/cmake/scripts/android/macros.cmake
+++ /dev/null
@@ -1 +0,0 @@
-../linux/macros.cmake
\ No newline at end of file
diff --git a/project/cmake/scripts/android/pathsetup.cmake b/project/cmake/scripts/android/pathsetup.cmake
deleted file mode 120000
index 26d7f17..0000000
--- a/project/cmake/scripts/android/pathsetup.cmake
+++ /dev/null
@@ -1 +0,0 @@
-../linux/pathsetup.cmake
\ No newline at end of file