10 files changed, 995 insertions, 24 deletions
diff --git a/project/cmake/scripts/common/addon-helpers.cmake b/project/cmake/scripts/common/addon-helpers.cmake
index b94df2a..9541df4 100644
--- a/project/cmake/scripts/common/addon-helpers.cmake
+++ b/project/cmake/scripts/common/addon-helpers.cmake
@@ -10,13 +10,23 @@ add_custom_target(addon-package
                  COMMAND ${CMAKE_COMMAND} --build ${CMAKE_BINARY_DIR} --target package)
 macro(add_cpack_workaround target version ext)
+  if(NOT PACKAGE_DIR)
+    set(PACKAGE_DIR "${CMAKE_INSTALL_PREFIX}/zips")
+  endif()
  add_custom_command(TARGET addon-package PRE_BUILD
-                     COMMAND ${CMAKE_COMMAND} -E rename addon-${target}-${version}.${ext} ${target}-${version}.${ext})
+                     COMMAND ${CMAKE_COMMAND} -E make_directory ${PACKAGE_DIR}
+                     COMMAND ${CMAKE_COMMAND} -E copy ${CPACK_PACKAGE_DIRECTORY}/addon-${target}-${version}.${ext} ${PACKAGE_DIR}/${target}-${version}.${ext})
 endmacro()
 # Grab the version from a given add-on's addon.xml
 macro (addon_version dir prefix)
-  FILE(READ ${dir}/addon.xml ADDONXML)
+  IF(EXISTS ${PROJECT_SOURCE_DIR}/${dir}/addon.xml.in)
+    FILE(READ ${PROJECT_SOURCE_DIR}/${dir}/addon.xml.in ADDONXML)
+  ELSE()
+    FILE(READ ${dir}/addon.xml ADDONXML)
+  ENDIF()
  STRING(REGEX MATCH "<addon[^>]*version.?=.?.[0-9\\.]+" VERSION_STRING ${ADDONXML}) 
  STRING(REGEX REPLACE ".*version=.([0-9\\.]+).*" "\\1" ${prefix}_VERSION ${VERSION_STRING})
  message(STATUS ${prefix}_VERSION=${${prefix}_VERSION})
@@ -34,6 +44,25 @@ macro (build_addon target prefix libs)
    SET_TARGET_PROPERTIES(${target} PROPERTIES PREFIX "lib")
  ENDIF(OS STREQUAL "android")
+  # get the library's location
+  SET(LIBRARY_LOCATION $<TARGET_FILE:${target}>)
+  # get the library's filename
+  if("${CORE_SYSTEM_NAME}" STREQUAL "android")
+    # for android we need the filename without any version numbers
+    set(LIBRARY_FILENAME $<TARGET_LINKER_FILE_NAME:${target}>)
+  else()
+    SET(LIBRARY_FILENAME $<TARGET_FILE_NAME:${target}>)
+  endif()
+  # if there's an addon.xml.in we need to generate the addon.xml
+  IF(EXISTS ${PROJECT_SOURCE_DIR}/${target}/addon.xml.in)
+    SET(PLATFORM ${CORE_SYSTEM_NAME})
+    FILE(READ ${PROJECT_SOURCE_DIR}/${target}/addon.xml.in addon_file)
+    STRING(CONFIGURE "${addon_file}" addon_file_conf @ONLY)
+    FILE(GENERATE OUTPUT ${PROJECT_SOURCE_DIR}/${target}/addon.xml CONTENT "${addon_file_conf}")
+  ENDIF()
  # set zip as default if addon-package is called without PACKAGE_XXX
  SET(CPACK_GENERATOR "ZIP")
  SET(ext "zip")
@@ -51,33 +80,62 @@ macro (build_addon target prefix libs)
    set(CPACK_COMPONENTS_IGNORE_GROUPS 1)
    list(APPEND CPACK_COMPONENTS_ALL ${target}-${${prefix}_VERSION})
    # Pack files together to create an archive
-    INSTALL(DIRECTORY ${target} DESTINATION ./ COMPONENT ${target}-${${prefix}_VERSION})
+    INSTALL(DIRECTORY ${target} DESTINATION ./ COMPONENT ${target}-${${prefix}_VERSION} PATTERN "addon.xml.in" EXCLUDE)
    IF(WIN32)
-      # get the installation location for the addon's target
+      if(NOT CPACK_PACKAGE_DIRECTORY)
-      get_property(dll_location TARGET ${target} PROPERTY LOCATION)
+        # determine the temporary path
+        file(TO_CMAKE_PATH "$ENV{TEMP}" WIN32_TEMP_PATH)
+        string(LENGTH "${WIN32_TEMP_PATH}" WIN32_TEMP_PATH_LENGTH)
+        string(LENGTH "${PROJECT_BINARY_DIR}" PROJECT_BINARY_DIR_LENGTH)
+        # check if the temporary path is shorter than the default packaging directory path
+        if(WIN32_TEMP_PATH_LENGTH GREATER 0 AND WIN32_TEMP_PATH_LENGTH LESS PROJECT_BINARY_DIR_LENGTH)
+          # set the directory used by CPack for packaging to the temp directory
+          set(CPACK_PACKAGE_DIRECTORY ${WIN32_TEMP_PATH})
+        endif()
+      endif()
      # in case of a VC++ project the installation location contains a $(Configuration) VS variable
      # we replace it with ${CMAKE_BUILD_TYPE} (which doesn't cover the case when the build configuration
      # is changed within Visual Studio)
-      string(REPLACE "$(Configuration)" "${CMAKE_BUILD_TYPE}" dll_location "${dll_location}")
+      string(REPLACE "$(Configuration)" "${CMAKE_BUILD_TYPE}" LIBRARY_LOCATION "${LIBRARY_LOCATION}")
      # install the generated DLL file
-      INSTALL(PROGRAMS ${dll_location} DESTINATION ${target}
+      INSTALL(PROGRAMS ${LIBRARY_LOCATION} DESTINATION ${target}
              COMPONENT ${target}-${${prefix}_VERSION})
      IF(CMAKE_BUILD_TYPE MATCHES Debug)
        # for debug builds also install the PDB file
-        get_filename_component(dll_directory ${dll_location} DIRECTORY)
+        get_filename_component(LIBRARY_DIR ${LIBRARY_LOCATION} DIRECTORY)
-        INSTALL(FILES ${dll_directory}/${target}.pdb DESTINATION ${target}
+        INSTALL(FILES ${LIBRARY_DIR}/${target}.pdb DESTINATION ${target}
                COMPONENT ${target}-${${prefix}_VERSION})
      ENDIF()
    ELSE(WIN32)
+      if(NOT CPACK_PACKAGE_DIRECTORY)
+        set(CPACK_PACKAGE_DIRECTORY ${CMAKE_BINARY_DIR})
+      endif()
      INSTALL(TARGETS ${target} DESTINATION ${target}
              COMPONENT ${target}-${${prefix}_VERSION})
    ENDIF(WIN32)
    add_cpack_workaround(${target} ${${prefix}_VERSION} ${ext})
  ELSE(PACKAGE_ZIP OR PACKAGE_TGZ)
-    INSTALL(TARGETS ${target} DESTINATION lib/kodi/addons/${target})
+    if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
-    INSTALL(DIRECTORY ${target} DESTINATION share/kodi/addons)
+      if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT OR NOT CMAKE_INSTALL_PREFIX)
+        message(STATUS "setting install paths to match ${APP_NAME}: CMAKE_INSTALL_PREFIX: ${${APP_NAME_UC}_PREFIX}")
+        set(CMAKE_INSTALL_PREFIX "${${APP_NAME_UC}_PREFIX}" CACHE PATH "${APP_NAME} install prefix" FORCE)
+        set(CMAKE_INSTALL_LIBDIR "${${APP_NAME_UC}_LIB_DIR}" CACHE PATH "${APP_NAME} install libdir" FORCE)
+      elseif(NOT CMAKE_INSTALL_PREFIX STREQUAL "${${APP_NAME_UC}_PREFIX}" AND NOT OVERRIDE_PATHS)
+        message(FATAL_ERROR "CMAKE_INSTALL_PREFIX ${CMAKE_INSTALL_PREFIX} differs from ${APP_NAME} prefix ${${APP_NAME_UC}_PREFIX}. Please pass -DOVERRIDE_PATHS=1 to skip this check")
+      else()
+        if(NOT CMAKE_INSTALL_LIBDIR)
+          set(CMAKE_INSTALL_LIBDIR "${CMAKE_INSTALL_PREFIX}/lib/${APP_NAME_LC}")
+        endif()
+      endif()
+    else()
+      set(CMAKE_INSTALL_LIBDIR "lib/${APP_NAME_LC}")
+    endif()
+    INSTALL(TARGETS ${target} DESTINATION ${CMAKE_INSTALL_LIBDIR}/addons/${target})
+    INSTALL(DIRECTORY ${target} DESTINATION share/${APP_NAME_LC}/addons PATTERN "addon.xml.in" EXCLUDE)
  ENDIF(PACKAGE_ZIP OR PACKAGE_TGZ)
 endmacro()
diff --git a/project/cmake/scripts/common/archsetup.cmake b/project/cmake/scripts/common/archsetup.cmake
new file mode 100644
index 0000000..dff5558
--- /dev/null
+++ b/project/cmake/scripts/common/archsetup.cmake
@@ -0,0 +1,99 @@
+# This script configures the build for a given architecture.
+# Flags and stringified arch is set up.
+# General compiler tests belongs here.
+#
+# On return, the following variables are set:
+# CMAKE_SYSTEM_NAME - a lowercased system name
+# CPU - the CPU on the target
+# ARCH - the system architecture
+# ARCH_DEFINES - list of compiler definitions for this architecture
+# SYSTEM_DEFINES - list of compiler definitions for this system
+# DEP_DEFINES - compiler definitions for system dependencies (e.g. LIRC)
+# + the results of compiler tests etc.
+include(CheckCXXSourceCompiles)
+include(CheckSymbolExists)
+include(CheckFunctionExists)
+# Macro to check if a given type exists in a given header
+# Arguments:
+#   header the header to check
+#   type   the type to check for existence
+#   var    the compiler definition to set if type exists
+# On return:
+#   If type was found, the definition is added to SYSTEM_DEFINES
+macro(check_type header type var)
+  check_cxx_source_compiles("#include <${header}>
+                             int main()
+                             {
+                               ${type} s;
+                             }" ${var})
+  if(${var})
+    list(APPEND SYSTEM_DEFINES -D${var}=1)
+  endif()
+endmacro()
+# Macro to check if a given builtin function exists
+# Arguments:
+#   func   the function to check
+#   var    the compiler definition to set if type exists
+# On return:
+#   If type was found, the definition is added to SYSTEM_DEFINES
+macro(check_builtin func var)
+  check_cxx_source_compiles("
+                             int main()
+                             {
+                               ${func};
+                             }" ${var})
+  if(${var})
+    list(APPEND SYSTEM_DEFINES -D${var}=1)
+  endif()
+endmacro()
+# -------- Main script --------- 
+message(STATUS "System type: ${CMAKE_SYSTEM_NAME}")
+if(NOT CORE_SYSTEM_NAME)
+  string(TOLOWER ${CMAKE_SYSTEM_NAME} CORE_SYSTEM_NAME)
+endif()
+if(WITH_CPU)
+  set(CPU ${WITH_CPU})
+elseif(NOT CMAKE_TOOLCHAIN_FILE)
+  set(CPU ${CMAKE_SYSTEM_PROCESSOR})
+endif()
+if(CMAKE_TOOLCHAIN_FILE)
+  if(NOT EXISTS "${CMAKE_TOOLCHAIN_FILE}")
+    message(FATAL_ERROR "Toolchain file ${CMAKE_TOOLCHAIN_FILE} does not exist.")
+  elseif(NOT DEPENDS_PATH OR NOT NATIVEPREFIX)
+    message(FATAL_ERROR "Toolchain did not define DEPENDS_PATH or NATIVEPREFIX. Possibly outdated depends.")
+  endif()
+endif()
+# Main cpp
+set(CORE_MAIN_SOURCE ${CORE_SOURCE_DIR}/xbmc/platform/posix/main.cpp)
+# system specific arch setup
+include(${PROJECT_SOURCE_DIR}/scripts/${CORE_SYSTEM_NAME}/archsetup.cmake)
+message(STATUS "Core system type: ${CORE_SYSTEM_NAME}")
+message(STATUS "Platform: ${PLATFORM}")
+message(STATUS "CPU: ${CPU}, ARCH: ${ARCH}")
+check_type(string std::u16string HAVE_STD__U16_STRING)
+check_type(string std::u32string HAVE_STD__U32_STRING)
+check_type(string char16_t HAVE_CHAR16_T)
+check_type(string char32_t HAVE_CHAR32_T)
+check_type(stdint.h uint_least16_t HAVE_STDINT_H)
+check_symbol_exists(posix_fadvise fcntl.h HAVE_POSIX_FADVISE)
+check_builtin("long* temp=0; long ret=__sync_add_and_fetch(temp, 1)" HAS_BUILTIN_SYNC_ADD_AND_FETCH)
+check_builtin("long* temp=0; long ret=__sync_sub_and_fetch(temp, 1)" HAS_BUILTIN_SYNC_SUB_AND_FETCH)
+check_builtin("long* temp=0; long ret=__sync_val_compare_and_swap(temp, 1, 1)" HAS_BUILTIN_SYNC_VAL_COMPARE_AND_SWAP)
+if(HAVE_POSIX_FADVISE)
+  list(APPEND SYSTEM_DEFINES -DHAVE_POSIX_FADVISE=1)
+endif()
+check_function_exists(localtime_r HAVE_LOCALTIME_R)
+if(HAVE_LOCALTIME_R)
+  list(APPEND SYSTEM_DEFINES -DHAVE_LOCALTIME_R=1)
+endif()
diff --git a/project/cmake/scripts/common/checkcommits.cmake b/project/cmake/scripts/common/checkcommits.cmake
new file mode 100644
index 0000000..304e623
--- /dev/null
+++ b/project/cmake/scripts/common/checkcommits.cmake
@@ -0,0 +1,75 @@
+find_package(Git REQUIRED)
+macro(sanity_check message)
+  if(status_code)
+    message(FATAL_ERROR "${message}")
+  endif()
+endmacro()
+# Check that there are no changes in working-tree
+execute_process(COMMAND ${GIT_EXECUTABLE} diff --quiet
+                RESULT_VARIABLE status_code)
+sanity_check("Cannot run with working tree changes. Commit, stash or drop them.")
+# Setup base of tests
+set(check_base $ENV{CHECK_BASE})
+if(NOT check_base)
+  set(check_base origin/master)
+endif()
+# Setup end of tests
+set(check_head $ENV{CHECK_HEAD})
+if(NOT check_head)
+  set(check_head HEAD)
+endif()
+# Setup target to build
+set(check_target $ENV{CHECK_TARGET})
+if(NOT check_target)
+  set(check_target check)
+endif()
+# Build threads
+set(build_threads $ENV{CHECK_THREADS})
+if(NOT build_threads)
+  if(UNIX)
+    execute_process(COMMAND nproc
+                    OUTPUT_VARIABLE build_threads)
+    string(REGEX REPLACE "(\r?\n)+$" "" build_threads "${build_threads}")
+  endif()
+endif()
+# Record current HEAD
+execute_process(COMMAND ${GIT_EXECUTABLE} rev-parse --abbrev-ref HEAD
+                OUTPUT_VARIABLE current_branch)
+string(REGEX REPLACE "(\r?\n)+$" "" current_branch "${current_branch}")
+# Grab revision list
+execute_process(COMMAND ${GIT_EXECUTABLE} rev-list ${check_base}..${check_head} --reverse
+                OUTPUT_VARIABLE rev_list)
+string(REPLACE "\n" ";" rev_list ${rev_list})
+foreach(rev ${rev_list})
+  # Checkout
+  message("Testing revision ${rev}")
+  execute_process(COMMAND ${GIT_EXECUTABLE} checkout ${rev}
+                  RESULT_VARIABLE status_code)
+  sanity_check("Failed to checkout ${rev}")
+  # Build
+  if(build_threads GREATER 2)
+    execute_process(COMMAND ${CMAKE_COMMAND} "--build" "${CMAKE_BINARY_DIR}" "--target" "${check_target}" "--use-stderr" "--" "-j${build_threads}"
+                    RESULT_VARIABLE status_code)
+  else()
+    execute_process(COMMAND ${CMAKE_COMMAND} "--build" "${CMAKE_BINARY_DIR}" "--target" "${check_target}" "--use-stderr"
+                    RESULT_VARIABLE status_code)
+  endif()
+  if(status_code)
+    execute_process(COMMAND ${GIT_EXECUTABLE} checkout ${current_branch})
+  endif()
+  sanity_check("Failed to build target for revision ${rev}")
+endforeach()
+message("Everything checks out fine")
+execute_process(COMMAND ${GIT_EXECUTABLE} checkout ${current_branch})
diff --git a/project/cmake/scripts/common/generateversionedfiles.cmake b/project/cmake/scripts/common/generateversionedfiles.cmake
new file mode 100644
index 0000000..9a4080a
--- /dev/null
+++ b/project/cmake/scripts/common/generateversionedfiles.cmake
@@ -0,0 +1,13 @@
+include(${CORE_SOURCE_DIR}/project/cmake/scripts/common/macros.cmake)
+core_find_versions()
+file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/addons/xbmc.addon)
+file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/addons/kodi.guilib)
+configure_file(${CORE_SOURCE_DIR}/addons/xbmc.addon/addon.xml.in
+               ${CMAKE_BINARY_DIR}/addons/xbmc.addon/addon.xml @ONLY)
+configure_file(${CORE_SOURCE_DIR}/addons/kodi.guilib/addon.xml.in
+               ${CMAKE_BINARY_DIR}/addons/kodi.guilib/addon.xml @ONLY)
+configure_file(${CORE_SOURCE_DIR}/xbmc/CompileInfo.cpp.in
+               ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/xbmc/CompileInfo.cpp @ONLY)
+set(prefix ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR})
+set(APP_LIBDIR ${CMAKE_BINARY_DIR}/${CORE_BUILD_DIR}/lib/kodi)
diff --git a/project/cmake/scripts/common/generatorsetup.cmake b/project/cmake/scripts/common/generatorsetup.cmake
new file mode 100644
index 0000000..75083ca
--- /dev/null
+++ b/project/cmake/scripts/common/generatorsetup.cmake
@@ -0,0 +1,24 @@
+# Configure single-/multiconfiguration generators and variables
+#
+# CORE_BUILD_CONFIG that is set to
+#   - CMAKE_BUILD_TYPE for single configuration generators such as make, nmake
+#   - a variable that expands on build time to the current configuration for
+#     multi configuration generators such as VS or Xcode
+if(CMAKE_CONFIGURATION_TYPES)
+  if(CMAKE_BUILD_TYPE)
+    message(FATAL_ERROR "CMAKE_BUILD_TYPE must not be defined for multi-configuration generators")
+  endif()
+  set(CORE_BUILD_CONFIG ${CMAKE_CFG_INTDIR})
+  message(STATUS "Generator: Multi-configuration (${CMAKE_GENERATOR})")
+else()
+  if(CMAKE_BUILD_TYPE)
+    set(CMAKE_BUILD_TYPE ${CMAKE_BUILD_TYPE}
+        CACHE STRING "Choose build type (${CMAKE_BUILD_TYPES})" FORCE)
+  else()
+    # Set default
+    set(CMAKE_BUILD_TYPE Release
+        CACHE STRING "Choose build type (${CMAKE_BUILD_TYPES})" FORCE)
+  endif()
+  set(CORE_BUILD_CONFIG ${CMAKE_BUILD_TYPE})
+  message(STATUS "Generator: Single-configuration: ${CMAKE_BUILD_TYPE} (${CMAKE_GENERATOR})")
+endif()
diff --git a/project/cmake/scripts/common/macros.cmake b/project/cmake/scripts/common/macros.cmake
new file mode 100644
index 0000000..dd2233b
--- /dev/null
+++ b/project/cmake/scripts/common/macros.cmake
@@ -0,0 +1,373 @@
+# This script holds the main functions used to construct the build system
+# include system specific macros
+include(${CORE_SOURCE_DIR}/project/cmake/scripts/${CORE_SYSTEM_NAME}/macros.cmake)
+# Add a library, optionally as a dependency of the main application
+# Arguments:
+#   name name of the library to add
+# Optional Arguments:
+#   NO_MAIN_DEPENDS if specified, the library is not added to main depends
+# Implicit arguments:
+#   SOURCES the sources of the library
+#   HEADERS the headers of the library (only for IDE support)
+#   OTHERS  other library related files (only for IDE support)
+# On return:
+#   Library will be built, optionally added to ${core_DEPENDS}
+function(core_add_library name)
+  cmake_parse_arguments(arg "NO_MAIN_DEPENDS" "" "" ${ARGN})
+  add_library(${name} STATIC ${SOURCES} ${HEADERS} ${OTHERS})
+  set_target_properties(${name} PROPERTIES PREFIX "")
+  if(NOT arg_NO_MAIN_DEPENDS)
+    set(core_DEPENDS ${name} ${core_DEPENDS} CACHE STRING "" FORCE)
+  endif()
+  # Add precompiled headers to Kodi main libraries
+  if(WIN32 AND "${CMAKE_CURRENT_LIST_DIR}" MATCHES "^${CORE_SOURCE_DIR}/xbmc")
+    add_precompiled_header(${name} pch.h ${CORE_SOURCE_DIR}/xbmc/win32/pch.cpp
+                           PCH_TARGET kodi)
+  endif()
+  # IDE support
+  if(CMAKE_GENERATOR MATCHES "Xcode")
+    file(RELATIVE_PATH parentfolder ${CORE_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/..)
+    set_target_properties(${name} PROPERTIES FOLDER "${parentfolder}")
+  elseif(CMAKE_GENERATOR MATCHES "Visual Studio")
+    file(RELATIVE_PATH foldername ${CORE_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR})
+    set_target_properties(${name} PROPERTIES FOLDER "${foldername}")
+    source_group(" " REGULAR_EXPRESSION ".*")
+  endif()
+endfunction()
+# Add a test library, and add sources to list for gtest integration macros
+function(core_add_test_library name)
+  core_add_library(${name} NO_MAIN_DEPENDS)
+  set_target_properties(${name} PROPERTIES EXCLUDE_FROM_ALL 1)
+  foreach(src ${SOURCES})
+    set(test_sources ${CMAKE_CURRENT_SOURCE_DIR}/${src} ${test_sources} CACHE STRING "" FORCE)
+  endforeach()
+  set(test_archives ${test_archives} ${name} CACHE STRING "" FORCE)
+endfunction()
+# Add a data file to installation list with a mirror in build tree
+# Arguments:
+#   file     full path to file to mirror
+#   relative the relative base of file path in the build/install tree
+#   give another parameter to exclude from install target
+# Implicit arguments:
+#   CORE_SOURCE_DIR - root of source tree
+# On return:
+#   file is added to ${install_data} and mirrored in build tree
+function(copy_file_to_buildtree file relative)
+  if(NOT WIN32)
+    string(REPLACE "\(" "\\(" file ${file})
+    string(REPLACE "\)" "\\)" file ${file})
+  endif()
+  string(REPLACE "${relative}/" "" outfile ${file})
+  if(NOT TARGET export-files)
+    add_custom_target(export-files ALL COMMENT "Copying files into build tree")
+  endif()
+  if(NOT ${CORE_SOURCE_DIR} MATCHES ${CMAKE_BINARY_DIR})
+    if(VERBOSE)
+      message(STATUS "copy_file_to_buildtree - copying file: ${file} -> ${CMAKE_CURRENT_BINARY_DIR}/${outfile}")
+    endif()
+    add_custom_command(TARGET export-files COMMAND ${CMAKE_COMMAND} -E copy_if_different "${file}" "${CMAKE_CURRENT_BINARY_DIR}/${outfile}")
+  endif()
+  if(NOT ARGN)
+    list(APPEND install_data ${outfile})
+    set(install_data ${install_data} PARENT_SCOPE)
+  endif()
+endfunction()
+# add data files to installation list with a mirror in build tree.
+# reads list of files to install from a given list of text files.
+# Arguments:
+#   pattern globbing pattern for text files to read
+#   give another parameter to exclude from installation target
+# Implicit arguments:
+#   CORE_SOURCE_DIR - root of source tree
+# On return:
+#   files are added to ${install_data} and mirrored in build tree
+function(copy_files_from_filelist_to_buildtree pattern)
+  foreach(arg ${ARGN})
+    list(APPEND pattern ${arg})
+  endforeach()
+  # copies files listed in text files to the buildtree
+  # Input: [glob pattern: filepattern]
+  list(SORT pattern)
+  if(VERBOSE)
+    message(STATUS "copy_files_from_filelist_to_buildtree - got pattern: ${pattern}")
+  endif()
+  foreach(pat ${pattern})
+    file(GLOB filenames ${pat})
+    foreach(filename ${filenames})
+      string(STRIP ${filename} filename)
+      core_file_read_filtered(fstrings ${filename})
+      foreach(dir ${fstrings})
+        file(GLOB_RECURSE files RELATIVE ${CORE_SOURCE_DIR} ${CORE_SOURCE_DIR}/${dir})
+        foreach(file ${files})
+          if(ARGN)
+            copy_file_to_buildtree(${CORE_SOURCE_DIR}/${file} ${CORE_SOURCE_DIR} 1)
+          else()
+            copy_file_to_buildtree(${CORE_SOURCE_DIR}/${file} ${CORE_SOURCE_DIR})
+          endif()
+        endforeach()
+      endforeach()
+    endforeach()
+  endforeach()
+  set(install_data ${install_data} PARENT_SCOPE)
+endfunction()
+# helper macro to set modified variables in parent scope
+macro(export_dep)
+  set(SYSTEM_INCLUDES ${SYSTEM_INCLUDES} PARENT_SCOPE)
+  set(DEPLIBS ${DEPLIBS} PARENT_SCOPE)
+  set(DEP_DEFINES ${DEP_DEFINES} PARENT_SCOPE)
+  set(${depup}_FOUND ${${depup}_FOUND} PARENT_SCOPE)
+  mark_as_advanced(${depup}_LIBRARIES)
+endmacro()
+# add a required dependency of main application
+# Arguments:
+#   dep name of find rule for dependency, used uppercased for variable prefix
+# On return:
+#   dependency added to ${SYSTEM_INCLUDES}, ${DEPLIBS} and ${DEP_DEFINES}
+function(core_require_dep dep)
+  find_package(${dep} REQUIRED)
+  string(TOUPPER ${dep} depup)
+  list(APPEND SYSTEM_INCLUDES ${${depup}_INCLUDE_DIRS})
+  list(APPEND DEPLIBS ${${depup}_LIBRARIES})
+  list(APPEND DEP_DEFINES ${${depup}_DEFINITIONS})
+  export_dep()
+endfunction()
+# add a required dyloaded dependency of main application
+# Arguments:
+#   dep name of find rule for dependency, used uppercased for variable prefix
+# On return:
+#   dependency added to ${SYSTEM_INCLUDES}, ${dep}_SONAME is set up
+function(core_require_dyload_dep dep)
+  find_package(${dep} REQUIRED)
+  string(TOUPPER ${dep} depup)
+  list(APPEND SYSTEM_INCLUDES ${${depup}_INCLUDE_DIRS})
+  list(APPEND DEP_DEFINES ${${depup}_DEFINITIONS})
+  find_soname(${depup} REQUIRED)
+  export_dep()
+  set(${depup}_SONAME ${${depup}_SONAME} PARENT_SCOPE)
+endfunction()
+# helper macro for optional deps
+macro(setup_enable_switch)
+  string(TOUPPER ${dep} depup)
+  if (ARGV1)
+    set(enable_switch ${ARGV1})
+  else()
+    set(enable_switch ENABLE_${depup})
+  endif()
+endmacro()
+# add an optional dependency of main application
+# Arguments:
+#   dep name of find rule for dependency, used uppercased for variable prefix
+# On return:
+#   dependency optionally added to ${SYSTEM_INCLUDES}, ${DEPLIBS} and ${DEP_DEFINES}
+function(core_optional_dep dep)
+  setup_enable_switch()
+  if(${enable_switch})
+    find_package(${dep})
+    if(${depup}_FOUND)
+      list(APPEND SYSTEM_INCLUDES ${${depup}_INCLUDE_DIRS})
+      list(APPEND DEPLIBS ${${depup}_LIBRARIES})
+      list(APPEND DEP_DEFINES ${${depup}_DEFINITIONS})
+      set(final_message ${final_message} "${depup} enabled: Yes" PARENT_SCOPE)
+      export_dep()
+    else()
+      set(final_message ${final_message} "${depup} enabled: No" PARENT_SCOPE)
+    endif()
+  endif()
+endfunction()
+# add an optional dyloaded dependency of main application
+# Arguments:
+#   dep name of find rule for dependency, used uppercased for variable prefix
+# On return:
+#   dependency optionally added to ${SYSTEM_INCLUDES}, ${DEP_DEFINES}, ${dep}_SONAME is set up
+function(core_optional_dyload_dep dep)
+  setup_enable_switch()
+  if(${enable_switch})
+    find_package(${dep})
+    if(${depup}_FOUND)
+      list(APPEND SYSTEM_INCLUDES ${${depup}_INCLUDE_DIRS})
+      find_soname(${depup} REQUIRED)
+      list(APPEND DEP_DEFINES ${${depup}_DEFINITIONS})
+      set(final_message ${final_message} "${depup} enabled: Yes" PARENT_SCOPE)
+      export_dep()
+      set(${depup}_SONAME ${${depup}_SONAME} PARENT_SCOPE)
+    endif()
+  endif()
+endfunction()
+function(core_file_read_filtered result filepattern)
+  # Reads STRINGS from text files
+  #  with comments filtered out
+  # Result: [list: result]
+  # Input:  [glob pattern: filepattern]
+  file(GLOB filenames ${filepattern})
+  list(SORT filenames)
+  foreach(filename ${filenames})
+    if(VERBOSE)
+      message(STATUS "core_file_read_filtered - filename: ${filename}")
+    endif()
+    file(STRINGS ${filename} fstrings REGEX "^[^#//]")
+    foreach(fstring ${fstrings})
+      string(REGEX REPLACE "^(.*)#(.*)" "\\1" fstring ${fstring})
+      string(REGEX REPLACE "//.*" "" fstring ${fstring})
+      string(STRIP ${fstring} fstring)
+      list(APPEND filename_strings ${fstring})
+    endforeach()
+  endforeach()
+  set(${result} ${filename_strings} PARENT_SCOPE)
+endfunction()
+function(core_add_subdirs_from_filelist files)
+  # Adds subdirectories from a sorted list of files
+  # Input: [list: filenames] [bool: sort]
+  foreach(arg ${ARGN})
+    list(APPEND files ${arg})
+  endforeach()
+  list(SORT files)
+  if(VERBOSE)
+    message(STATUS "core_add_subdirs_from_filelist - got pattern: ${files}")
+  endif()
+  foreach(filename ${files})
+    string(STRIP ${filename} filename)
+    core_file_read_filtered(fstrings ${filename})
+    foreach(subdir ${fstrings})
+      STRING_SPLIT(subdir " " ${subdir})
+      list(GET subdir  0 subdir_src)
+      list(GET subdir -1 subdir_dest)
+      if(VERBOSE)
+        message(STATUS "  core_add_subdirs_from_filelist - adding subdir: ${CORE_SOURCE_DIR}${subdir_src} -> ${CORE_BUILD_DIR}/${subdir_dest}")
+      endif()
+      add_subdirectory(${CORE_SOURCE_DIR}/${subdir_src} ${CORE_BUILD_DIR}/${subdir_dest})
+    endforeach()
+  endforeach()
+endfunction()
+macro(core_add_optional_subdirs_from_filelist pattern)
+  # Adds subdirectories from text files
+  #  if the option(s) in the 3rd field are enabled
+  # Input: [glob pattern: filepattern]
+  foreach(arg ${ARGN})
+    list(APPEND pattern ${arg})
+  endforeach()
+  foreach(elem ${pattern})
+    string(STRIP ${elem} elem)
+    list(APPEND filepattern ${elem})
+  endforeach()
+  file(GLOB filenames ${filepattern})
+  list(SORT filenames)
+  if(VERBOSE)
+    message(STATUS "core_add_optional_subdirs_from_filelist - got pattern: ${filenames}")
+  endif()
+  foreach(filename ${filenames})
+    if(VERBOSE)
+      message(STATUS "core_add_optional_subdirs_from_filelist - reading file: ${filename}")
+    endif()
+    file(STRINGS ${filename} fstrings REGEX "^[^#//]")
+    foreach(line ${fstrings})
+      string(REPLACE " " ";" line "${line}")
+      list(GET line 0 subdir_src)
+      list(GET line 1 subdir_dest)
+      list(GET line 3 opts)
+      foreach(opt ${opts})
+        if(ENABLE_${opt})
+          if(VERBOSE)
+            message(STATUS "  core_add_optional_subdirs_from_filelist - adding subdir: ${CORE_SOURCE_DIR}${subdir_src} -> ${CORE_BUILD_DIR}/${subdir_dest}")
+          endif()
+          add_subdirectory(${CORE_SOURCE_DIR}/${subdir_src} ${CORE_BUILD_DIR}/${subdir_dest})
+         else()
+            if(VERBOSE)
+              message(STATUS "  core_add_optional_subdirs_from_filelist: OPTION ${opt} not enabled for ${subdir_src}, skipping subdir")
+            endif()
+        endif()
+      endforeach()
+    endforeach()
+  endforeach()
+endmacro()
+macro(today RESULT)
+  if (WIN32)
+    execute_process(COMMAND "cmd" " /C date /T" OUTPUT_VARIABLE ${RESULT})
+    string(REGEX REPLACE "(..)/(..)/..(..).*" "\\1/\\2/\\3" ${RESULT} ${${RESULT}})
+  elseif(UNIX)
+    execute_process(COMMAND date -u +%F
+                    OUTPUT_VARIABLE ${RESULT})
+    string(REGEX REPLACE "(..)/(..)/..(..).*" "\\1/\\2/\\3" ${RESULT} ${${RESULT}})
+  else()
+    message(SEND_ERROR "date not implemented")
+    set(${RESULT} 000000)
+  endif()
+  string(REGEX REPLACE "(\r?\n)+$" "" ${RESULT} "${${RESULT}}")
+endmacro()
+function(core_find_git_rev)
+  if(EXISTS ${CORE_SOURCE_DIR}/VERSION)
+    file(STRINGS ${CORE_SOURCE_DIR}/VERSION VERSION_FILE)
+    string(SUBSTRING "${VERSION_FILE}" 1 16 GIT_REV)
+  else()
+    find_package(Git)
+    if(GIT_FOUND AND EXISTS ${CORE_SOURCE_DIR}/.git)
+      execute_process(COMMAND ${GIT_EXECUTABLE} diff-files --ignore-submodules --quiet --
+                      RESULT_VARIABLE status_code
+                      WORKING_DIRECTORY ${CORE_SOURCE_DIR})
+      if (NOT status_code)
+        execute_process(COMMAND ${GIT_EXECUTABLE} diff-index --cached --ignore-submodules --quiet HEAD --
+                        RESULT_VARIABLE status_code
+                        WORKING_DIRECTORY ${CORE_SOURCE_DIR})
+      endif()
+      today(DATE)
+      execute_process(COMMAND ${GIT_EXECUTABLE} --no-pager log --abbrev=7 -n 1
+                                                --pretty=format:"%h-dirty" HEAD
+                      OUTPUT_VARIABLE LOG_UNFORMATTED
+                      WORKING_DIRECTORY ${CORE_SOURCE_DIR})
+      string(SUBSTRING ${LOG_UNFORMATTED} 1 7 HASH)
+    else()
+      execute_process(COMMAND ${GIT_EXECUTABLE} --no-pager log --abbrev=7 -n 1
+                                                --pretty=format:"%h %cd" HEAD
+                      OUTPUT_VARIABLE LOG_UNFORMATTED
+                      WORKING_DIRECTORY ${CORE_SOURCE_DIR})
+      string(SUBSTRING ${LOG_UNFORMATTED} 1 7 HASH)
+      string(SUBSTRING ${LOG_UNFORMATTED} 9 10 DATE)
+      string(REPLACE "-" "" DATE ${DATE})
+    endif()
+    set(GIT_REV "${DATE}-${HASH}")
+  endif()
+  if(GIT_REV)
+    set(APP_SCMID ${GIT_REV} PARENT_SCOPE)
+  endif()
+endfunction()
+macro(core_find_versions)
+  include(CMakeParseArguments)
+  core_file_read_filtered(version_list ${CORE_SOURCE_DIR}/version.txt)
+  string(REPLACE " " ";" version_list "${version_list}")
+  cmake_parse_arguments(APP "" "VERSION_MAJOR;VERSION_MINOR;VERSION_TAG;VERSION_CODE;ADDON_API;APP_NAME;COMPANY_NAME" "" ${version_list})
+  set(APP_NAME ${APP_APP_NAME}) # inconsistency in upstream
+  string(TOLOWER ${APP_APP_NAME} APP_NAME_LC)
+  set(COMPANY_NAME ${APP_COMPANY_NAME})
+  set(APP_VERSION ${APP_VERSION_MAJOR}.${APP_VERSION_MINOR})
+  if(APP_VERSION_TAG)
+    set(APP_VERSION ${APP_VERSION}-${APP_VERSION_TAG})
+  endif()
+  string(REPLACE "." "," FILE_VERSION ${APP_ADDON_API}.0)
+  string(TOLOWER ${APP_VERSION_TAG} APP_VERSION_TAG_LC)
+  file(STRINGS ${CORE_SOURCE_DIR}/xbmc/addons/kodi-addon-dev-kit/include/kodi/libKODI_guilib.h guilib_version REGEX "^.*GUILIB_API_VERSION (.*)$")
+  string(REGEX REPLACE ".*\"(.*)\"" "\\1" guilib_version ${guilib_version})
+  file(STRINGS ${CORE_SOURCE_DIR}/xbmc/addons/kodi-addon-dev-kit/include/kodi/libKODI_guilib.h guilib_version_min REGEX "^.*GUILIB_MIN_API_VERSION (.*)$")
+  string(REGEX REPLACE ".*\"(.*)\"" "\\1" guilib_version_min ${guilib_version_min})
+endmacro()
diff --git a/project/cmake/scripts/common/managestring.cmake b/project/cmake/scripts/common/managestring.cmake
new file mode 100644
index 0000000..7321f4c
--- /dev/null
+++ b/project/cmake/scripts/common/managestring.cmake
@@ -0,0 +1,235 @@
+# - Collection of String utility macros.
+# Defines the following macros:
+#   STRING_TRIM(var str [NOUNQUOTE])
+#   - Trim a string by removing the leading and trailing spaces,
+#     just like STRING(STRIP ...) in CMake 2.6 and later.
+#     This macro is needed as CMake 2.4 does not support STRING(STRIP ..)
+#     This macro also remove quote and double quote marks around the string,
+#     unless NOUNQUOTE is defined.
+#     * Parameters:
+#       + var: A variable that stores the result.
+#       + str: A string.
+#       + NOUNQUOTE: (Optional) do not remove the double quote mark around the string.
+#
+#   STRING_UNQUOTE(var str)
+#   - Remove double quote marks and quote marks around a string.
+#     If the string is not quoted, then it returns an empty string.
+#     * Parameters:
+#       + var: A variable that stores the result.
+#       + str: A string.
+#
+#   STRING_JOIN(var delimiter str_list [str...])
+#   - Concatenate strings, with delimiter inserted between strings.
+#     * Parameters:
+#       + var: A variable that stores the result.
+#       + str_list: A list of string.
+#       + str: (Optional) more string to be join.
+#
+#   STRING_SPLIT(var delimiter str [NOESCAPE_SEMICOLON])
+#   - Split a string into a list using a delimiter, which can be in 1 or more
+#     characters long.
+#     * Parameters:
+#       + var: A variable that stores the result.
+#       + delimiter: To separate a string.
+#       + str: A string.
+#       + NOESCAPE_SEMICOLON: (Optional) Do not escape semicolons.
+#
+IF(NOT DEFINED _MANAGE_STRING_CMAKE_)
+    SET(_MANAGE_STRING_CMAKE_ "DEFINED")
+    MACRO(STRING_TRIM var str)
+        SET(${var} "")
+        IF (NOT "${ARGN}" STREQUAL "NOUNQUOTE")
+            # Need not trim a quoted string.
+            STRING_UNQUOTE(_var "${str}")
+            IF(NOT _var STREQUAL "")
+                # String is quoted
+                SET(${var} "${_var}")
+            ENDIF(NOT _var STREQUAL "")
+        ENDIF(NOT "${ARGN}" STREQUAL "NOUNQUOTE")
+        IF(${var} STREQUAL "")
+            SET(_var_1 "${str}")
+            STRING(REGEX REPLACE  "^[ \t\r\n]+" "" _var_2 "${str}" )
+            STRING(REGEX REPLACE  "[ \t\r\n]+$" "" _var_3 "${_var_2}" )
+            SET(${var} "${_var_3}")
+        ENDIF(${var} STREQUAL "")
+    ENDMACRO(STRING_TRIM var str)
+    # Internal macro
+    # Variable cannot be escaped here, as variable is already substituted
+    # at the time it passes to this macro.
+    MACRO(STRING_ESCAPE var str)
+        # ';' and '\' are tricky, need to be encoded.
+        # '#' => '#H'
+        # '\' => '#B'
+        # ';' => '#S'
+        SET(_NOESCAPE_SEMICOLON "")
+        SET(_NOESCAPE_HASH "")
+        FOREACH(_arg ${ARGN})
+            IF(${_arg} STREQUAL "NOESCAPE_SEMICOLON")
+                SET(_NOESCAPE_SEMICOLON "NOESCAPE_SEMICOLON")
+            ELSEIF(${_arg} STREQUAL "NOESCAPE_HASH")
+                SET(_NOESCAPE_HASH "NOESCAPE_HASH")
+            ENDIF(${_arg} STREQUAL "NOESCAPE_SEMICOLON")
+        ENDFOREACH(_arg)
+        IF(_NOESCAPE_HASH STREQUAL "")
+            STRING(REGEX REPLACE "#" "#H" _ret "${str}")
+        ELSE(_NOESCAPE_HASH STREQUAL "")
+            SET(_ret "${str}")
+        ENDIF(_NOESCAPE_HASH STREQUAL "")
+        STRING(REGEX REPLACE "\\\\" "#B" _ret "${_ret}")
+        IF(_NOESCAPE_SEMICOLON STREQUAL "")
+            STRING(REGEX REPLACE ";" "#S" _ret "${_ret}")
+        ENDIF(_NOESCAPE_SEMICOLON STREQUAL "")
+        SET(${var} "${_ret}")
+    ENDMACRO(STRING_ESCAPE var str)
+    MACRO(STRING_UNESCAPE var str)
+        # '#B' => '\'
+        # '#H' => '#'
+        # '#D' => '$'
+        # '#S' => ';'
+        SET(_ESCAPE_VARIABLE "")
+        SET(_NOESCAPE_SEMICOLON "")
+        SET(_ret "${str}")
+        FOREACH(_arg ${ARGN})
+            IF(${_arg} STREQUAL "NOESCAPE_SEMICOLON")
+                SET(_NOESCAPE_SEMICOLON "NOESCAPE_SEMICOLON")
+            ELSEIF(${_arg} STREQUAL "ESCAPE_VARIABLE")
+                SET(_ESCAPE_VARIABLE "ESCAPE_VARIABLE")
+                STRING(REGEX REPLACE "#D" "$" _ret "${_ret}")
+            ENDIF(${_arg} STREQUAL "NOESCAPE_SEMICOLON")
+        ENDFOREACH(_arg)
+        STRING(REGEX REPLACE "#B" "\\\\" _ret "${_ret}")
+        IF(_NOESCAPE_SEMICOLON STREQUAL "")
+            # ';' => '#S'
+            STRING(REGEX REPLACE "#S" "\\\\;" _ret "${_ret}")
+        ELSE(_NOESCAPE_SEMICOLON STREQUAL "")
+            STRING(REGEX REPLACE "#S" ";" _ret "${_ret}")
+        ENDIF(_NOESCAPE_SEMICOLON STREQUAL "")
+        IF(NOT _ESCAPE_VARIABLE STREQUAL "")
+            # '#D' => '$'
+            STRING(REGEX REPLACE "#D" "$" _ret "${_ret}")
+        ENDIF(NOT _ESCAPE_VARIABLE STREQUAL "")
+        STRING(REGEX REPLACE "#H" "#" _ret "${_ret}")
+        SET(${var} "${_ret}")
+    ENDMACRO(STRING_UNESCAPE var str)
+    MACRO(STRING_UNQUOTE var str)
+        STRING_ESCAPE(_ret "${str}" ${ARGN})
+        IF(_ret MATCHES "^[ \t\r\n]+")
+            STRING(REGEX REPLACE "^[ \t\r\n]+" "" _ret "${_ret}")
+        ENDIF(_ret MATCHES "^[ \t\r\n]+")
+        IF(_ret MATCHES "^\"")
+            # Double quote
+            STRING(REGEX REPLACE "\"\(.*\)\"[ \t\r\n]*$" "\\1" _ret "${_ret}")
+        ELSEIF(_ret MATCHES "^'")
+            # Single quote
+            STRING(REGEX REPLACE "'\(.*\)'[ \t\r\n]*$" "\\1" _ret "${_ret}")
+        ELSE(_ret MATCHES "^\"")
+            SET(_ret "")
+        ENDIF(_ret MATCHES "^\"")
+        # Unencoding
+        STRING_UNESCAPE(${var} "${_ret}" ${ARGN})
+    ENDMACRO(STRING_UNQUOTE var str)
+    MACRO(STRING_JOIN var delimiter str_list)
+        SET(_ret "")
+        FOREACH(_str ${str_list})
+            IF(_ret STREQUAL "")
+                SET(_ret "${_str}")
+            ELSE(_ret STREQUAL "")
+                SET(_ret "${_ret}${delimiter}${_str}")
+            ENDIF(_ret STREQUAL "")
+        ENDFOREACH(_str ${str_list})
+        FOREACH(_str ${ARGN})
+            IF(_ret STREQUAL "")
+                SET(_ret "${_str}")
+            ELSE(_ret STREQUAL "")
+                SET(_ret "${_ret}${delimiter}${_str}")
+            ENDIF(_ret STREQUAL "")
+        ENDFOREACH(_str ${str_list})
+        SET(${var} "${_ret}")
+    ENDMACRO(STRING_JOIN var delimiter str_list)
+    MACRO(STRING_SPLIT var delimiter str)
+        SET(_max_tokens "")
+        SET(_NOESCAPE_SEMICOLON "")
+        SET(_ESCAPE_VARIABLE "")
+        FOREACH(_arg ${ARGN})
+            IF(${_arg} STREQUAL "NOESCAPE_SEMICOLON")
+                SET(_NOESCAPE_SEMICOLON "NOESCAPE_SEMICOLON")
+            ELSEIF(${_arg} STREQUAL "ESCAPE_VARIABLE")
+                SET(_ESCAPE_VARIABLE "ESCAPE_VARIABLE")
+            ELSE(${_arg} STREQUAL "NOESCAPE_SEMICOLON")
+                SET(_max_tokens ${_arg})
+            ENDIF(${_arg} STREQUAL "NOESCAPE_SEMICOLON")
+        ENDFOREACH(_arg)
+        IF(NOT _max_tokens)
+            SET(_max_tokens -1)
+        ENDIF(NOT _max_tokens)
+        STRING_ESCAPE(_str "${str}" ${_NOESCAPE_SEMICOLON} ${_ESCAPE_VARIABLE})
+        STRING_ESCAPE(_delimiter "${delimiter}" ${_NOESCAPE_SEMICOLON} ${_ESCAPE_VARIABLE})
+        SET(_str_list "")
+        SET(_token_count 0)
+        STRING(LENGTH "${_delimiter}" _de_len)
+        WHILE(NOT _token_count EQUAL _max_tokens)
+            MATH(EXPR _token_count ${_token_count}+1)
+            IF(_token_count EQUAL _max_tokens)
+                # Last token, no need splitting
+                SET(_str_list ${_str_list} "${_str}")
+            ELSE(_token_count EQUAL _max_tokens)
+                # in case encoded characters are delimiters
+                STRING(LENGTH "${_str}" _str_len)
+                SET(_index 0)
+                SET(_token "")
+                SET(_str_remain "")
+                MATH(EXPR _str_end ${_str_len}-${_de_len}+1)
+                SET(_bound "k")
+                WHILE(_index LESS _str_end)
+                    STRING(SUBSTRING "${_str}" ${_index} ${_de_len} _str_cursor)
+                    IF(_str_cursor STREQUAL _delimiter)
+                        # Get the token
+                        STRING(SUBSTRING "${_str}" 0 ${_index} _token)
+                        # Get the rest
+                        MATH(EXPR _rest_index ${_index}+${_de_len})
+                        MATH(EXPR _rest_len ${_str_len}-${_index}-${_de_len})
+                        STRING(SUBSTRING "${_str}" ${_rest_index} ${_rest_len} _str_remain)
+                        SET(_index ${_str_end})
+                    ELSE(_str_cursor STREQUAL _delimiter)
+                        MATH(EXPR _index ${_index}+1)
+                    ENDIF(_str_cursor STREQUAL _delimiter)
+                ENDWHILE(_index LESS _str_end)
+                IF(_str_remain STREQUAL "")
+                    # Meaning: end of string
+                    LIST(APPEND _str_list "${_str}")
+                    SET(_max_tokens ${_token_count})
+                ELSE(_str_remain STREQUAL "")
+                    LIST(APPEND _str_list "${_token}")
+                    SET(_str "${_str_remain}")
+                ENDIF(_str_remain STREQUAL "")
+            ENDIF(_token_count EQUAL _max_tokens)
+        ENDWHILE(NOT _token_count EQUAL _max_tokens)
+        # Unencoding
+        STRING_UNESCAPE(${var} "${_str_list}" ${_NOESCAPE_SEMICOLON} ${_ESCAPE_VARIABLE})
+    ENDMACRO(STRING_SPLIT var delimiter str)
+ENDIF(NOT DEFINED _MANAGE_STRING_CMAKE_)
diff --git a/project/cmake/scripts/common/pathsetup.cmake b/project/cmake/scripts/common/pathsetup.cmake
new file mode 100644
index 0000000..54b352d
--- /dev/null
+++ b/project/cmake/scripts/common/pathsetup.cmake
@@ -0,0 +1,3 @@
+# This script configures installation paths
+include(${PROJECT_SOURCE_DIR}/scripts/${CORE_SYSTEM_NAME}/pathsetup.cmake)
diff --git a/project/cmake/scripts/common/prepare-env.cmake b/project/cmake/scripts/common/prepare-env.cmake
index 3413c45..b9a39e7 100644
--- a/project/cmake/scripts/common/prepare-env.cmake
+++ b/project/cmake/scripts/common/prepare-env.cmake
@@ -12,6 +12,8 @@ if(EXISTS "${APP_ROOT}/version.txt")
      set(${name} "${value}")
    endif()
  endforeach()
+  string(TOLOWER ${APP_NAME} APP_NAME_LC)
+  string(TOUPPER ${APP_NAME} APP_NAME_UC)
 endif()
 # bail if we can't parse versions
@@ -19,16 +21,21 @@ if(NOT DEFINED APP_VERSION_MAJOR OR NOT DEFINED APP_VERSION_MINOR)
  message(FATAL_ERROR "Could not determine app version! make sure that ${APP_ROOT}/version.txt exists")
 endif()
+# in case we need to download something, set KODI_MIRROR to the default if not alread set
+if(NOT DEFINED KODI_MIRROR)
+  set(KODI_MIRROR "http://mirrors.kodi.tv")
+endif()
 ### copy all the addon binding header files to include/kodi
 # make sure include/kodi exists and is empty
-set(KODI_LIB_DIR ${DEPENDS_PATH}/lib/kodi)
+set(APP_LIB_DIR ${DEPENDS_PATH}/lib/${APP_NAME_LC})
-if(NOT EXISTS "${KODI_LIB_DIR}/")
+if(NOT EXISTS "${APP_LIB_DIR}/")
-  file(MAKE_DIRECTORY ${KODI_LIB_DIR})
+  file(MAKE_DIRECTORY ${APP_LIB_DIR})
 endif()
-set(KODI_INCLUDE_DIR ${DEPENDS_PATH}/include/kodi)
+set(APP_INCLUDE_DIR ${DEPENDS_PATH}/include/${APP_NAME_LC})
-if(NOT EXISTS "${KODI_INCLUDE_DIR}/")
+if(NOT EXISTS "${APP_INCLUDE_DIR}/")
-  file(MAKE_DIRECTORY ${KODI_INCLUDE_DIR})
+  file(MAKE_DIRECTORY ${APP_INCLUDE_DIR})
 endif()
 # we still need XBMC_INCLUDE_DIR and XBMC_LIB_DIR for backwards compatibility to xbmc
@@ -49,13 +56,13 @@ if(NOT WIN32)
  endif()
 endif()
-# kodi-config.cmake.in (further down) expects a "prefix" variable
-get_filename_component(prefix "${DEPENDS_PATH}" ABSOLUTE)
 # generate the proper kodi-config.cmake file
-configure_file(${APP_ROOT}/project/cmake/kodi-config.cmake.in ${KODI_LIB_DIR}/kodi-config.cmake @ONLY)
+configure_file(${APP_ROOT}/project/cmake/kodi-config.cmake.in ${APP_LIB_DIR}/kodi-config.cmake @ONLY)
 # copy cmake helpers to lib/kodi
-file(COPY ${APP_ROOT}/project/cmake/scripts/common/addon-helpers.cmake ${APP_ROOT}/project/cmake/scripts/common/addoptions.cmake DESTINATION ${KODI_LIB_DIR})
+file(COPY ${APP_ROOT}/project/cmake/scripts/common/addon-helpers.cmake
+          ${APP_ROOT}/project/cmake/scripts/common/addoptions.cmake
+     DESTINATION ${APP_LIB_DIR})
 # generate xbmc-config.cmake for backwards compatibility to xbmc
 configure_file(${APP_ROOT}/project/cmake/xbmc-config.cmake.in ${XBMC_LIB_DIR}/xbmc-config.cmake @ONLY)
@@ -69,7 +76,7 @@ foreach(binding ${bindings})
  string(REPLACE "+=" ";" binding "${binding}")
  list(GET binding 1 header)
  # copy the header file to include/kodi
-  file(COPY ${APP_ROOT}/${header} DESTINATION ${KODI_INCLUDE_DIR})
+  file(COPY ${APP_ROOT}/${header} DESTINATION ${APP_INCLUDE_DIR})
  # auto-generate header files for backwards compatibility to xbmc with deprecation warning
  # but only do it if the file doesn't already exist
@@ -95,7 +102,7 @@ if(WIN32)
  else()
    set(PATCH_ARCHIVE_NAME "patch-2.5.9-7-bin-1")
    set(PATCH_ARCHIVE "${PATCH_ARCHIVE_NAME}.zip")
-    set(PATCH_URL "http://mirrors.xbmc.org/build-deps/win32/${PATCH_ARCHIVE}")
+    set(PATCH_URL "${KODI_MIRROR}/build-deps/win32/${PATCH_ARCHIVE}")
    set(PATCH_DOWNLOAD ${BUILD_DIR}/download/${PATCH_ARCHIVE})
    # download the archive containing patch.exe
diff --git a/project/cmake/scripts/common/projectmacros.cmake b/project/cmake/scripts/common/projectmacros.cmake
new file mode 100644
index 0000000..d0739c4
--- /dev/null
+++ b/project/cmake/scripts/common/projectmacros.cmake
@@ -0,0 +1,84 @@
+# This script holds macros which are project specific
+# Pack a skin xbt file
+# Arguments:
+#   input  input directory to pack
+#   output ouput xbt file
+# On return:
+#   xbt is added to ${XBT_FILES}
+function(pack_xbt input output)
+  file(GLOB_RECURSE MEDIA_FILES ${input}/*)
+  get_filename_component(dir ${output} PATH)
+  add_custom_command(OUTPUT  ${output}
+                     COMMAND ${CMAKE_COMMAND} -E make_directory ${dir}
+                     COMMAND TexturePacker::TexturePacker
+                     ARGS    -input ${input}
+                             -output ${output}
+                             -dupecheck
+                     DEPENDS ${MEDIA_FILES})
+  list(APPEND XBT_FILES ${output})
+  set(XBT_FILES ${XBT_FILES} PARENT_SCOPE)
+endfunction()
+# Add a skin to installation list, mirroring it in build tree, packing textures
+# Arguments:
+#   skin     skin directory
+#   relative relative base path in build tree
+# On return:
+#   xbt is added to ${XBT_FILES}, data added to ${install_data}, mirror in build tree
+function(copy_skin_to_buildtree skin relative)
+  file(GLOB_RECURSE FILES ${skin}/*)
+  file(GLOB_RECURSE MEDIA_FILES ${skin}/media/*)
+  list(REMOVE_ITEM FILES ${MEDIA_FILES})
+  foreach(file ${FILES})
+    copy_file_to_buildtree(${file} ${relative})
+  endforeach()
+  file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/${dest}/media)
+  string(REPLACE "${relative}/" "" dest ${skin})
+  pack_xbt(${skin}/media
+           ${CMAKE_BINARY_DIR}/${dest}/media/Textures.xbt
+           ${CMAKE_BINARY_DIR})
+                
+  set(XBT_FILES ${XBT_FILES} PARENT_SCOPE)
+  set(install_data ${install_data} PARENT_SCOPE)
+endfunction()
+# Get GTest tests as CMake tests.
+# Copied from FindGTest.cmake 
+# Thanks to Daniel Blezek <blezek@gmail.com> for the GTEST_ADD_TESTS code
+function(GTEST_ADD_TESTS executable extra_args)
+    if(NOT ARGN)
+        message(FATAL_ERROR "Missing ARGN: Read the documentation for GTEST_ADD_TESTS")
+    endif()
+    foreach(source ${ARGN})
+        file(READ "${source}" contents)
+        string(REGEX MATCHALL "TEST_?[F]?\\(([A-Za-z_0-9 ,]+)\\)" found_tests ${contents})
+        foreach(hit ${found_tests})
+            string(REGEX REPLACE ".*\\( *([A-Za-z_0-9]+), *([A-Za-z_0-9]+) *\\).*" "\\1.\\2" test_name ${hit})
+            add_test(${test_name} ${executable} --gtest_filter=${test_name} ${extra_args})
+        endforeach()
+        # Groups parametrized tests under a single ctest entry
+        string(REGEX MATCHALL "INSTANTIATE_TEST_CASE_P\\(([^,]+), *([^,]+)" found_tests2 ${contents})
+        foreach(hit ${found_tests2})
+          string(SUBSTRING ${hit} 24 -1 test_name)
+          string(REPLACE "," ";" test_name "${test_name}")
+          list(GET test_name 0 filter_name)
+          list(GET test_name 1 test_prefix)
+          string(STRIP ${test_prefix} test_prefix)
+          add_test(${test_prefix}.${filter_name} ${executable} --gtest_filter=${filter_name}* ${extra_args})
+        endforeach()
+    endforeach()
+endfunction()
+function(whole_archive output)
+  if(CMAKE_CXX_COMPILER_ID STREQUAL GNU OR CMAKE_CXX_COMPILER_ID STREQUAL Clang)
+    set(${output} -Wl,--whole-archive ${ARGN} -Wl,--no-whole-archive PARENT_SCOPE)
+  elseif(CMAKE_CXX_COMPILER_ID STREQUAL AppleClang)
+    foreach(library ${ARGN})
+      list(APPEND ${output} -Wl,-force_load ${library})
+      set(${output} ${${output}} PARENT_SCOPE)
+    endforeach()
+  else()
+    set(${output} ${ARGN} PARENT_SCOPE)
+  endif()
+endfunction()